new file: Math/omega_prime_numbers_in_range_simple.pl

Author: trizen

Math/omega_prime_numbers_in_range.pl

@@ -33,10 +33,8 @@ ($A, $B, $k, $callback)
                 if ($k == 1) {
                     $callback->($v) if ($v >= $A);
                 }
-                else {
-                    if (mulint($v, $r) <= $B) {
-                         __SUB__->($v, $r, $k - 1);
-                    }
+                elsif (mulint($v, $r) <= $B) {
+                    __SUB__->($v, $r, $k - 1);
                 }
             }
         }

Math/omega_prime_numbers_in_range_simple.pl

@@ -0,0 +1,74 @@
+#!/usr/bin/perl
+
+# Daniel "Trizen" Șuteu
+# Date: 14 March 2021
+# Edit: 25 March 2025
+# https://github.com/trizen
+
+# Generate k-omega primes in range [a,b]. (not in sorted order)
+
+# Definition:
+#   k-omega primes are numbers n such that omega(n) = k.
+
+# See also:
+#   https://en.wikipedia.org/wiki/Almost_prime
+#   https://en.wikipedia.org/wiki/Prime_omega_function
+
+use 5.020;
+use integer;
+use ntheory      qw(:all);
+use experimental qw(signatures);
+
+sub omega_prime_numbers ($A, $B, $k, $callback) {
+
+    $A = vecmax($A, pn_primorial($k));
+
+    sub ($m, $p, $k) {
+
+        my $s = rootint($B / $m, $k);
+
+        foreach my $q (@{primes($p, $s)}) {
+
+            my $r = next_prime($q);
+
+            for (my $v = $m * $q ; $v <= $B ; $v *= $q) {
+                if ($k == 1) {
+                    $callback->($v) if ($v >= $A);
+                }
+                elsif ($v * $r <= $B) {
+                    __SUB__->($v, $r, $k - 1);
+                }
+            }
+        }
+    }->(1, 2, $k);
+}
+
+# Generate 5-omega primes in the range [3000, 10000]
+
+my $k    = 5;
+my $from = 3000;
+my $upto = 10000;
+
+my @arr;
+omega_prime_numbers($from, $upto, $k, sub ($n) { push @arr, $n });
+
+my @test = grep { prime_omega($_) == $k } $from .. $upto;    # just for testing
+join(' ', sort { $a <=> $b } @arr) eq join(' ', @test) or die "Error: not equal!";
+
+say join(', ', @arr);
+
+# Run some tests
+
+foreach my $k (1 .. 6) {
+
+    my $from = pn_primorial($k) + int(rand(1e4));
+    my $upto = $from + int(rand(1e5));
+
+    say "Testing: $k with $from .. $upto";
+
+    my @arr;
+    omega_prime_numbers($from, $upto, $k, sub ($n) { push @arr, $n });
+
+    my @test = grep { prime_omega($_) == $k } $from .. $upto;
+    join(' ', sort { $a <=> $b } @arr) eq join(' ', @test) or die "Error: not equal!";
+}

README.md

@@ -997,6 +997,7 @@ A nice collection of day-to-day Perl scripts.
     * [Omega prime divisors](./Math/omega_prime_divisors.pl)
     * [Omega prime numbers in range](./Math/omega_prime_numbers_in_range.pl)
     * [Omega prime numbers in range mpz](./Math/omega_prime_numbers_in_range_mpz.pl)
+    * [Omega prime numbers in range simple](./Math/omega_prime_numbers_in_range_simple.pl)
     * [Order factorization method](./Math/order_factorization_method.pl)
     * [Palindrome iteration](./Math/palindrome_iteration.pl)
     * [Partial sums of dedekind psi function](./Math/partial_sums_of_dedekind_psi_function.pl)