code review

Author: mshinwell

driver/compenv.ml

@@ -206,9 +206,17 @@ let read_OCAMLPARAM ppf position =
 
       (* inlining *)
       | "inline" ->
-        Float_arg_helper.parse v
-          "Bad syntax in OCAMLPARAM for 'inline'"
-          inline_threshold
+          let module F = Float_arg_helper in
+          begin match F.parse_no_error v inline_threshold with
+          | F.Ok -> ()
+          | F.Parse_failed exn ->
+              let error =
+                Printf.sprintf "bad syntax for \"inline\": %s"
+                  (Printexc.to_string exn)
+              in
+              Location.print_warning Location.none ppf
+                (Warnings.Bad_env_variable ("OCAMLPARAM", error))
+          end
 
       (* color output *)
       | "color" ->

utils/arg_helper.ml

@@ -42,45 +42,59 @@ end) = struct
     | exception Not_found -> true
     | _index -> false
 
-  let parse str ~help_text ~update =
+  exception Parse_failure of exn
+
+  let parse_exn str ~update =
     let values = Misc.Stdlib.String.split str ~on:',' in
     let parsed =
       List.fold_left (fun acc value ->
           match String.index value '=' with
           | exception Not_found ->
             begin match S.Value.of_string value with
             | value -> { acc with default = value }
-            | exception exn ->
-              fatal (Printf.sprintf "%s: %s" (Printexc.to_string exn) help_text)
+            | exception exn -> raise (Parse_failure exn)
             end
           | equals ->
             let key_value_pair = value in
             let length = String.length key_value_pair in
-            if equals <= 0 || equals >= length - 1 then begin
-              fatal help_text
+            assert (equals >= 0 && equals < length);
+            if equals = 0 then begin
+              raise (Parse_failure (
+                Failure "Missing key in argument specification"))
             end;
             let key =
               let key = String.sub key_value_pair 0 equals in
               try S.Key.of_string key
-              with exn ->
-                fatal (Printf.sprintf "%s: %s"
-                         (Printexc.to_string exn) help_text)
+              with exn -> raise (Parse_failure exn)
             in
             let value =
               let value =
                 String.sub key_value_pair (equals + 1) (length - equals - 1)
               in
               try S.Value.of_string value
-              with exn ->
-                fatal (Printf.sprintf "%s: %s"
-                         (Printexc.to_string exn) help_text)
+              with exn -> raise (Parse_failure exn)
             in
             { acc with override = S.Key.Map.add key value acc.override })
         !update
         values
     in
     update := parsed
 
+  let parse str ~help_text ~update =
+    match parse_exn str ~update with
+    | () -> ()
+    | exception (Parse_failure exn) ->
+      fatal (Printf.sprintf "%s: %s" (Printexc.to_string exn) help_text)
+
+  type parse_result =
+    | Ok
+    | Parse_failed of exn
+
+  let parse_no_error str ~update =
+    match parse_exn str ~update with
+    | () -> Ok
+    | exception (Parse_failure exn) -> Parse_failed exn
+
   let get ~key parsed =
     match S.Key.Map.find key parsed.override with
     | provided -> provided

utils/arg_helper.mli

@@ -33,7 +33,7 @@ module Make (S : sig
   module Value : sig
     type t
 
-    (** The textual representation of a value must not contain '=' or ','. *)
+    (** The textual representation of a value must not contain ','. *)
     val of_string : string -> t
   end
 end) : sig
@@ -46,5 +46,11 @@ end) : sig
 
   val parse : string -> help_text:string -> update:parsed ref -> unit
 
+  type parse_result =
+    | Ok
+    | Parse_failed of exn
+
+  val parse_no_error : string -> update:parsed ref -> parse_result
+
   val get : key:S.Key.t -> parsed -> S.Value.t
 end

utils/clflags.mli

@@ -18,6 +18,12 @@ module Int_arg_helper : sig
   }
 
   val parse : string -> help_text:string -> update:parsed ref -> unit
+
+  type parse_result =
+    | Ok
+    | Parse_failed of exn
+  val parse_no_error : string -> update:parsed ref -> parse_result
+
   val get : key:int -> parsed -> int
 end
 
@@ -29,6 +35,12 @@ module Float_arg_helper : sig
   }
 
   val parse : string -> help_text:string -> update:parsed ref -> unit
+
+  type parse_result =
+    | Ok
+    | Parse_failed of exn
+  val parse_no_error : string -> update:parsed ref -> parse_result
+
   val get : key:int -> parsed -> float
 end