Converted android example to use Kotlin Gradle DSL

Author: AOrobator

examples/counter/android/build.gradle renamed to examples/counter/android/build.gradle.kts

@@ -1,17 +1,11 @@
-apply plugin: 'com.android.application'
-
-apply plugin: 'kotlin-android'
-
-apply plugin: 'kotlin-android-extensions'
-
-apply plugin: 'kotlin-kapt'
-
+plugins {
+    id("com.android.application")
+    kotlin("android")
+    kotlin("android.extensions")
+    kotlin("kapt")
+}
 
 android {
-    compileOptions {
-        sourceCompatibility = JavaVersion.VERSION_1_8
-        targetCompatibility = JavaVersion.VERSION_1_8
-    }
     compileSdkVersion(29)
     defaultConfig {
         applicationId = "org.reduxkotlin.example.counter"
@@ -21,27 +15,30 @@ android {
         versionName = "1.0"
         testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
     }
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_1_8
+        targetCompatibility = JavaVersion.VERSION_1_8
+    }
     buildTypes {
-        release {
-            minifyEnabled = false
-            proguardFiles(getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro')
+        getByName("release") {
+            isMinifyEnabled = false
+            proguardFiles(getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro")
         }
-        debug {
+        getByName("debug") {
             // MPP libraries don't currently get this resolution automatically
-            matchingFallbacks = ['release']
+            matchingFallbacks = listOf("release")
         }
     }
     packagingOptions {
-        exclude 'META-INF/*.kotlin_module'
+        exclude("META-INF/*.kotlin_module")
     }
-    tasks.lint.enabled = false
 }
 
 
 dependencies {
     implementation(Libs.kotlin_stdlib_jdk8)
     implementation(Libs.appcompat)
 
-    implementation(project(':examples:counter:common'))
-    implementation(project(':lib'))
+    implementation(project(":examples:counter:common"))
+    implementation(project(":lib"))
 }