build.gradle

repositories {
    maven { url "https://dl.bintray.com/spekframework/spek-dev" }
}
apply plugin: 'java'
apply plugin: 'kotlin-multiplatform'


kotlin {
    jvm()
    js() {
        [compileKotlinJs, compileTestKotlinJs].each { configuration ->
            configuration.kotlinOptions {
                moduleKind = 'umd'
                sourceMap = true
                metaInfo = true
            }
        }
    }


    iosArm64("ios")
    iosX64("iosSim")
    macosX64("macos")
    mingwX64("win")
    wasm32("wasm")
    linuxArm32Hfp("linArm32")
    linuxMips32("linMips32")
    linuxMipsel32("linMipsel32")
    linuxX64("lin64")

    sourceSets {
        commonMain {
            dependencies {
                implementation kotlin("stdlib-common")
                implementation project(":redux-kotlin")
            }
        }
        commonTest {
            kotlin.srcDir('src/test/kotlin')
            dependencies {
                implementation kotlin("test-common")
                implementation kotlin("test-annotations-common")
                implementation "org.spekframework.spek2:spek-dsl-metadata:$Versions.spek"
                implementation "ch.tutteli.atrium:atrium-cc-en_GB-robstoll-common:$Versions.atrium"
                implementation "io.mockk:mockk-common:$Versions.mockk"
            }
        }

        jvmMain {
            kotlin.srcDir('src/jvmMain/kotlin')
            dependencies {
                implementation kotlin("stdlib")
            }
        }
        jvmTest {
            dependencies {
                implementation kotlin("test")
                implementation kotlin("test-junit")
                implementation "org.spekframework.spek2:spek-dsl-jvm:$Versions.spek"
                implementation "ch.tutteli.atrium:atrium-cc-en_GB-robstoll:$Versions.atrium"
                implementation "io.mockk:mockk:$Versions.mockk"

                runtimeOnly "org.spekframework.spek2:spek-runner-junit5:$Versions.spek"
                runtimeOnly 'org.jetbrains.kotlin:kotlin-reflect'
            }
        }
        jsMain {
            kotlin.srcDir('src/jsMain/kotlin')
            dependencies {
                implementation kotlin("stdlib-js")
            }
            compileKotlinJs {
                kotlinOptions.metaInfo = true
                kotlinOptions.sourceMap = true
                kotlinOptions.verbose = true
                kotlinOptions.main = "call"
                kotlinOptions.moduleKind = "umd"
            }
        }
        jsTest {
            dependencies {
                implementation kotlin("test-js")
                implementation kotlin("stdlib-js")
            }
        }

        iosSimMain.dependsOn iosMain
        iosSimTest.dependsOn iosTest
    }
}

jvmTest {
    useJUnitPlatform {
        includeEngines 'spek2'
    }
}