-
Notifications
You must be signed in to change notification settings - Fork 139
/
Copy pathPPCArrayCopy.inc
2706 lines (2538 loc) · 66.7 KB
/
PPCArrayCopy.inc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! Copyright IBM Corp. and others 2000
!!
!! This program and the accompanying materials are made available under
!! the terms of the Eclipse Public License 2.0 which accompanies this
!! distribution and is available at https://www.eclipse.org/legal/epl-2.0/
!! or the Apache License, Version 2.0 which accompanies this distribution
!! and is available at https://www.apache.org/licenses/LICENSE-2.0.
!!
!! This Source Code may also be made available under the following Secondary
!! Licenses when the conditions for such availability set forth in the
!! Eclipse Public License, v. 2.0 are satisfied: GNU General Public License,
!! version 2 with the GNU Classpath Exception [1] and GNU General Public
!! License, version 2 with the OpenJDK Assembly Exception [2].
!!
!! [1] https://www.gnu.org/software/classpath/license.html
!! [2] https://openjdk.org/legal/assembly-exception.html
!!
!! SPDX-License-Identifier: EPL-2.0 OR Apache-2.0 OR GPL-2.0-only WITH Classpath-exception-2.0 OR GPL-2.0-only WITH OpenJDK-assembly-exception-1.0
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! arrayCopy*, wordArrayCopy*, halfWordArrayCopy*, forwardArrayCopy*,
! forwardWordArrayCopy*, forwardHalfWordArrayCopy*:
! copyByteLength -- r7
! srcByteAddr -- r8
! dstByteAddr -- r9
! 64-bit kills: r0, r5, r6, r7, r8, r9, r11, cr0
! 32-bit kills: r0, r3, r4, r5, r6, r7, r8, r9, r10, r11, cr0
! 32-bit float additionally kills: fp8, fp9, fp10, fp11
! float double pair additionally kills: fp8, fp9, fp10, fp11
#include "p/runtime/ppcasmdefines.inc"
.set LONG_LENGTH, 33;
#ifdef AIXPPC
.globl .__arrayCopy
.globl __arrayCopy{DS}
.globl .__wordArrayCopy
.globl __wordArrayCopy{DS}
.globl .__halfWordArrayCopy
.globl __halfWordArrayCopy{DS}
.globl .__forwardArrayCopy
.globl __forwardArrayCopy{DS}
.globl .__forwardWordArrayCopy
.globl __forwardWordArrayCopy{DS}
.globl .__forwardHalfWordArrayCopy
.globl __forwardHalfWordArrayCopy{DS}
.globl .__arrayCopy_dp
.globl __arrayCopy_dp{DS}
.globl .__wordArrayCopy_dp
.globl __wordArrayCopy_dp{DS}
.globl .__halfWordArrayCopy_dp
.globl __halfWordArrayCopy_dp{DS}
.globl .__forwardArrayCopy_dp
.globl __forwardArrayCopy_dp{DS}
.globl .__forwardWordArrayCopy_dp
.globl __forwardWordArrayCopy_dp{DS}
.globl .__forwardHalfWordArrayCopy_dp
.globl __forwardHalfWordArrayCopy_dp{DS}
.globl .__forwardQuadWordArrayCopy_vsx
.globl __forwardQuadWordArrayCopy_vsx{DS}
.globl .__quadWordArrayCopy_vsx
.globl __quadWordArrayCopy_vsx{DS}
.globl .__postP10ForwardCopy
.globl __postP10ForwardCopy{DS}
.globl .__postP10GenericCopy
.globl __postP10GenericCopy{DS}
.lglobl .__codeForShortArrayCopy
.lglobl L.0copy
.lglobl L.1copy
.lglobl L.2copy
.lglobl L.3copy
.lglobl L.4copy
.lglobl L.5copy
.lglobl L.6copy
.lglobl L.7copy
.lglobl L.8copy
.lglobl L.9copy
.lglobl L.10copy
.lglobl L.11copy
.lglobl L.12copy
.lglobl L.13copy
.lglobl L.14copy
.lglobl L.15copy
.lglobl L.16copy
.lglobl L.17copy
.lglobl L.18copy
.lglobl L.19copy
.lglobl L.20copy
.lglobl L.21copy
.lglobl L.22copy
.lglobl L.23copy
.lglobl L.24copy
.lglobl L.25copy
.lglobl L.26copy
.lglobl L.27copy
.lglobl L.28copy
.lglobl L.29copy
.lglobl L.30copy
.lglobl L.31copy
.lglobl L.32copy
#elif defined(LINUXPPC64)
.globl FUNC_LABEL(__arrayCopy)
.type FUNC_LABEL(__arrayCopy),@function
.globl FUNC_LABEL(__wordArrayCopy)
.type FUNC_LABEL(__wordArrayCopy),@function
.globl FUNC_LABEL(__halfWordArrayCopy)
.type FUNC_LABEL(__halfWordArrayCopy),@function
.globl FUNC_LABEL(__forwardArrayCopy)
.type FUNC_LABEL(__forwardArrayCopy),@function
.globl FUNC_LABEL(__forwardWordArrayCopy)
.type FUNC_LABEL(__forwardWordArrayCopy),@function
.globl FUNC_LABEL(__forwardHalfWordArrayCopy)
.type FUNC_LABEL(__forwardHalfWordArrayCopy),@function
.globl FUNC_LABEL(__arrayCopy_dp)
.type FUNC_LABEL(__arrayCopy_dp),@function
.globl FUNC_LABEL(__wordArrayCopy_dp)
.type FUNC_LABEL(__wordArrayCopy_dp),@function
.globl FUNC_LABEL(__halfWordArrayCopy_dp)
.type FUNC_LABEL(__halfWordArrayCopy_dp),@function
.globl FUNC_LABEL(__forwardArrayCopy_dp)
.type FUNC_LABEL(__forwardArrayCopy_dp),@function
.globl FUNC_LABEL(__forwardWordArrayCopy_dp)
.type FUNC_LABEL(__forwardWordArrayCopy_dp),@function
.globl FUNC_LABEL(__forwardHalfWordArrayCopy_dp)
.type FUNC_LABEL(__forwardHalfWordArrayCopy_dp),@function
.globl FUNC_LABEL(__forwardQuadWordArrayCopy_vsx)
.type FUNC_LABEL(__forwardQuadWordArrayCopy_vsx),@function
.globl FUNC_LABEL(__quadWordArrayCopy_vsx)
.type FUNC_LABEL(__quadWordArrayCopy_vsx),@function
.globl FUNC_LABEL(__postP10ForwardCopy)
.type FUNC_LABEL(__postP10ForwardCopy),@function
.globl FUNC_LABEL(__postP10GenericCopy)
.type FUNC_LABEL(__postP10GenericCopy),@function
#elif defined(LINUX)
.globl __arrayCopy
.globl __wordArrayCopy
.globl __halfWordArrayCopy
.globl __forwardArrayCopy
.globl __forwardWordArrayCopy
.globl __forwardHalfWordArrayCopy
.globl __arrayCopy_dp
.globl __wordArrayCopy_dp
.globl __halfWordArrayCopy_dp
.globl __forwardArrayCopy_dp
.globl __forwardWordArrayCopy_dp
.globl __forwardHalfWordArrayCopy_dp
.globl __forwardQuadWordArrayCopy_vsx
.globl __quadWordArrayCopy_vsx
.globl __postP10ForwardCopy
.globl __postP10GenericCopy
#endif
#if defined(LINUXPPC64)
.section ".text"
.align 2
#endif
#ifdef AIXPPC
.csect __arrayCopy{PR}
.__arrayCopy:
.function .__arrayCopy,startproc.__arrayCopy,16,0,(endproc.__arrayCopy-startproc.__arrayCopy)
#elif defined(LINUXPPC64)
FUNC_LABEL(__arrayCopy):
#else
__arrayCopy:
#endif
startproc.__arrayCopy:
L.__arrayCopy:
cmpli cr0, CmpAddr, r7, LONG_LENGTH ! Decide if it is a long copy
subf r11, r8, r9
bc BO_IF, CR0_LT, .L.tableDispatch
cmpl cr0, CmpAddr, r11, r7 ! Reverse copy or not
bc BO_IF, CR0_LT, .L.reverseArrayCopy
.L.testOddAddressed:
andi. r11, r8, 1 ! Source aligned on PPC
bc BO_IF, CR0_EQ, .L.testHalfWordAlign
lbz r11, 0(r8)
addi r8, r8, 1
addi r7, r7, -1
stb r11, 0(r9)
addi r9, r9, 1
.L.testHalfWordAlign:
andi. r11, r8, 2
bc BO_IF, CR0_EQ, .L.wordAligned
lhz r11, 0(r8)
addi r7, r7, -2
addi r8, r8, 2
cmpli cr0, CmpAddr, r7, LONG_LENGTH
sth r11, 0(r9)
addi r9, r9, 2
bc BO_IF, CR0_LT, .L.tableDispatch
.L.wordAligned:
#ifdef TR_HOST_64BIT
! Some older non-PPC-AS processors may take aligment interrupts on fixed
! doubleword loads and stores that are not word aligned (the 630 for
! example). We will ignore the performance issue there and always use
! doublewords in a 64-bit environment.
andi. r11, r8, 4
bc BO_IF, CR0_EQ, .L.dWordAligned
lwz r11, 0(r8)
addi r7, r7, -4
addi r8, r8, 4
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stw r11, 0(r9)
addi r9, r9, 4
bc BO_IF, CR0_LT, .L.tableDispatch
.L.dWordAligned:
srdi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11
.L.dWordLoop:
ld r6, 0(r8)
ld r5, 8(r8)
ld r0, 16(r8)
ld r11, 24(r8)
addi r8, r8, 32
std r6, 0(r9)
std r5, 8(r9)
std r0, 16(r9)
std r11, 24(r9)
addi r9, r9, 32
bdnz .L.dWordLoop
bclr BO_IF, CR0_EQ
#else
! On some processors, a float doubleword load/store that is not word aligned
! will take an alignment interrupt. If the target is not word aligned, fall
! back on using fixed word loads/stores.
andi. r11, r9, 3
bc BO_IF_NOT, CR0_EQ, .L.targetMisaligned
andi. r11, r8, 4
bc BO_IF, CR0_EQ, .L.dWordAligned
lwz r11, 0(r8)
addi r7, r7, -4
addi r8, r8, 4
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stw r11, 0(r9)
addi r9, r9, 4
bc BO_IF, CR0_LT, .L.tableDispatch
.L.dWordAligned:
srwi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11
.L.dWordLoop:
lfd fp11, 0(r8)
lfd fp10, 8(r8)
lfd fp9, 16(r8)
lfd fp8, 24(r8)
addi r8, r8, 32
stfd fp11, 0(r9)
stfd fp10, 8(r9)
stfd fp9, 16(r9)
stfd fp8, 24(r9)
addi r9, r9, 32
bdnz .L.dWordLoop
bclr BO_IF, CR0_EQ
b .L.tableDispatch
.L.targetMisaligned:
srwi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11
.L.wordLoop:
lwz r6, 0(r8)
lwz r5, 4(r8)
lwz r0, 8(r8)
lwz r11, 12(r8)
stw r6, 0(r9)
stw r5, 4(r9)
stw r0, 8(r9)
stw r11, 12(r9)
lwz r6, 16(r8)
lwz r5, 20(r8)
lwz r0, 24(r8)
lwz r11, 28(r8)
addi r8, r8, 32
stw r6, 16(r9)
stw r5, 20(r9)
stw r0, 24(r9)
stw r11, 28(r9)
addi r9, r9, 32
bdnz .L.wordLoop
bclr BO_IF, CR0_EQ
#endif
.L.tableDispatch:
dcbt r0, r8
dcbtst r0, r9
laddr r11, J9TR_VMThreadRTOCOffset(J9VM_STRUCT) ! Restore TOC/GOT
#ifdef TR_HOST_64BIT
rlwinm r7, r7, 3, 0xFFFFFFF8
#else
rlwinm r7, r7, 2, 0xFFFFFFFC
#endif
#ifdef AIXPPC
laddr r11, TOC__shortArrayCopyLabelTable(r11)
#elif defined(LINUXPPC64)
laddr r11, TOC__shortArrayCopyLabelTable@toc(r11)
#else
laddr r11, __shortArrayCopyLabelTable@got(r11)
#endif
laddrx r11, r11, r7
mtctr r11
bctr
.L.reverseArrayCopy:
add r8, r8, r7
add r9, r9, r7
andi. r11, r8, 1
bc BO_IF, CR0_EQ, .L.testReverseHalfWordAlign
lbzu r11, -1(r8)
addi r7, r7, -1
stbu r11, -1(r9)
.L.testReverseHalfWordAlign:
andi. r11, r8, 2
bc BO_IF, CR0_EQ, .L.reverseWordAligned
addi r7, r7, -2
lhzu r11, -2(r8)
cmpli cr0, CmpAddr, r7, LONG_LENGTH
sthu r11, -2(r9)
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.reverseWordAligned:
#ifdef TR_HOST_64BIT
! Some older non-PPC-AS processors may take aligment interrupts on fixed
! doubleword loads and stores that are not word aligned (the 630 for
! example). We will ignore the performance issue there and always use
! doublewords in a 64-bit environment.
andi. r11, r8, 4
bc BO_IF, CR0_EQ, .L.reverseDWordAligned
addi r7, r7, -4
lwzu r11, -4(r8)
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stwu r11, -4(r9)
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.reverseDWordAligned:
srdi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11
.L.reverseDWordLoop:
ld r6, -8(r8)
ld r5, -16(r8)
ld r0, -24(r8)
ldu r11, -32(r8)
std r6, -8(r9)
std r5, -16(r9)
std r0, -24(r9)
stdu r11, -32(r9)
bdnz .L.reverseDWordLoop
bclr BO_IF, CR0_EQ
#else
! On some processors, a float doubleword load/store that is not word aligned
! will take an alignment interrupt. If the target is not word aligned, fall
! back on using fixed word loads/stores.
andi. r11, r9, 3
bc BO_IF_NOT, CR0_EQ, .L.reverseTargetMisaligned
andi. r11, r8, 4
bc BO_IF, CR0_EQ, .L.reverseDWordAligned
addi r7, r7, -4
lwzu r11, -4(r8)
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stwu r11, -4(r9)
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.reverseDWordAligned:
srwi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11
.L.reverseDWordLoop:
lfd fp11, -8(r8)
lfd fp10, -16(r8)
lfd fp9, -24(r8)
lfdu fp8, -32(r8)
stfd fp11, -8(r9)
stfd fp10, -16(r9)
stfd fp9, -24(r9)
stfdu fp8, -32(r9)
bdnz .L.reverseDWordLoop
bclr BO_IF, CR0_EQ
b .L.reverseTableDispatch
.L.reverseTargetMisaligned:
srwi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11
.L.reverseWordLoop:
lwz r6, -4(r8)
lwz r5, -8(r8)
lwz r0, -12(r8)
lwz r11, -16(r8)
stw r6, -4(r9)
stw r5, -8(r9)
stw r0, -12(r9)
stw r11, -16(r9)
lwz r6, -20(r8)
lwz r5, -24(r8)
lwz r0, -28(r8)
lwzu r11, -32(r8)
stw r6, -20(r9)
stw r5, -24(r9)
stw r0, -28(r9)
stwu r11, -32(r9)
bdnz .L.reverseWordLoop
bclr BO_IF, CR0_EQ
#endif
.L.reverseTableDispatch:
subf r8, r7, r8
subf r9, r7, r9
b .L.tableDispatch
endproc.__arrayCopy:
#ifdef AIXPPC
.csect __wordArrayCopy{PR}
.__wordArrayCopy:
.function .__wordArrayCopy,startproc.__wordArrayCopy,16,0,(endproc.__wordArrayCopy-startproc.__wordArrayCopy)
#elif defined(LINUXPPC64)
FUNC_LABEL(__wordArrayCopy):
#else
__wordArrayCopy:
#endif
startproc.__wordArrayCopy:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
subf r11, r8, r9
bc BO_IF, CR0_LT, .L.tableDispatch
cmpl cr0, CmpAddr, r11, r7
bc BO_IF_NOT, CR0_LT, .L.wordAligned
add r8, r8, r7
add r9, r9, r7
b .L.reverseWordAligned
endproc.__wordArrayCopy:
#ifdef AIXPPC
.csect __halfWordArrayCopy{PR}
.__halfWordArrayCopy:
.function .__halfWordArrayCopy,startproc.__halfWordArrayCopy,16,0,(endproc.__halfWordArrayCopy-startproc.__halfWordArrayCopy)
#elif defined(LINUXPPC64)
FUNC_LABEL(__halfWordArrayCopy):
#else
__halfWordArrayCopy:
#endif
startproc.__halfWordArrayCopy:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
subf r11, r8, r9
bc BO_IF, CR0_LT, .L.tableDispatch
cmpl cr0, CmpAddr, r11, r7
bc BO_IF_NOT, CR0_LT, .L.testHalfWordAlign
add r8, r8, r7
add r9, r9, r7
b .L.testReverseHalfWordAlign
endproc.__halfWordArrayCopy:
#ifdef AIXPPC
.csect __forwardArrayCopy{PR}
.__forwardArrayCopy:
.function .__forwardArrayCopy,startproc.__forwardArrayCopy,16,0,(endproc.__forwardArrayCopy-startproc.__forwardArrayCopy)
#elif defined(LINUXPPC64)
FUNC_LABEL(__forwardArrayCopy):
#else
__forwardArrayCopy:
#endif
startproc.__forwardArrayCopy:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
bc BO_IF, CR0_LT, .L.tableDispatch
b .L.testOddAddressed
endproc.__forwardArrayCopy:
#ifdef AIXPPC
.csect __forwardWordArrayCopy{PR}
.__forwardWordArrayCopy:
.function .__forwardWordArrayCopy,startproc.__forwardWordArrayCopy,16,0,(endproc.__forwardWordArrayCopy-startproc.__forwardWordArrayCopy)
#elif defined(LINUXPPC64)
FUNC_LABEL(__forwardWordArrayCopy):
#else
__forwardWordArrayCopy:
#endif
startproc.__forwardWordArrayCopy:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
bc BO_IF, CR0_LT, .L.tableDispatch
b .L.wordAligned
endproc.__forwardWordArrayCopy:
#ifdef AIXPPC
.csect __forwardHalfWordArrayCopy{PR}
.__forwardHalfWordArrayCopy:
.function .__forwardHalfWordArrayCopy,startproc.__forwardHalfWordArrayCopy,16,0,(endproc.__forwardHalfWordArrayCopy-startproc.__forwardHalfWordArrayCopy)
#elif defined(LINUXPPC64)
FUNC_LABEL(__forwardHalfWordArrayCopy):
#else
__forwardHalfWordArrayCopy:
#endif
startproc.__forwardHalfWordArrayCopy:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
bc BO_IF, CR0_LT, .L.tableDispatch
b .L.testHalfWordAlign
endproc.__forwardHalfWordArrayCopy:
! This code is for POWER6 and later processors that support store float
! double pair instructions. The code is scheduled for a POWER6.
#ifdef AIXPPC
.csect __arrayCopy_dp{PR}, 5
.__arrayCopy_dp:
.function .__arrayCopy_dp,startproc.__arrayCopy_dp,16,0,(endproc.__arrayCopy_dp-startproc.__arrayCopy_dp)
#elif defined(LINUXPPC64)
.align 5
FUNC_LABEL(__arrayCopy_dp):
#elif defined(LINUX)
.align 5
__arrayCopy_dp:
#else
__arrayCopy_dp:
#endif
startproc.__arrayCopy_dp:
cmpli cr0, CmpAddr, r7, LONG_LENGTH ! Decide if it is a long copy
subf r11, r8, r9
bc BO_IF, CR0_LT, .L.tableDispatch
cmpl cr0, CmpAddr, r11, r7 ! Reverse copy or not
bc BO_IF, CR0_LT, .L.reverseArrayCopy_dp
.L.testOddAddressed_dp:
andi. r11, r9, 1 ! Destination aligned on PPC
bc BO_IF, CR0_EQ, .L.testHalfWordAlign_dp
lbz r11, 0(r8)
addi r8, r8, 1
addi r7, r7, -1
stb r11, 0(r9)
addi r9, r9, 1
.L.testHalfWordAlign_dp:
andi. r11, r9, 2
bc BO_IF, CR0_EQ, .L.wordAligned_dp
lhz r11, 0(r8)
addi r7, r7, -2
addi r8, r8, 2
cmpli cr0, CmpAddr, r7, LONG_LENGTH
sth r11, 0(r9)
addi r9, r9, 2
bc BO_IF, CR0_LT, .L.tableDispatch
.L.wordAligned_dp:
! On a P6 processor stores that cross an 8B boundary cause two store
! operations from the core to the GPS, and that will cause a slowdown if
! the store queue becomes full.
andi. r11, r9, 4
bc BO_IF, CR0_EQ, .L.dWordAligned_dp
lwz r11, 0(r8)
addi r7, r7, -4
addi r8, r8, 4
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stw r11, 0(r9)
addi r9, r9, 4
bc BO_IF, CR0_LT, .L.tableDispatch
.L.dWordAligned_dp:
! Destination is doubleword (8-byte) aligned.
! On a P6 processor a floating point load/store that is not word aligned
! will take an alignment interrupt. If the source is not word aligned, fall
! back on using fixed point doubleword loads/stores.
andi. r11, r8, 7
bc BO_IF_NOT, CR0_EQ, .L.sourceMisaligned_dp
! To use stfdp we need to align the destination on a 16-byte boundary.
andi. r11, r9, 8
bc BO_IF, CR0_EQ, .L.qWordAligned_dp
lfd fp8, 0(r8)
addi r7, r7, -8
addi r8, r8, 8
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stfd fp8, 0(r9)
addi r9, r9, 8
bc BO_IF, CR0_LT, .L.tableDispatch
#if defined(AIXPPC) || defined(LINUX) || defined(LINUXPPC64)
.align 5 ! force 32-byte I-cache sector alignment here
#endif
.L.qWordAligned_dp:
#ifdef TR_HOST_64BIT
srdi. r11, r7, 6 ! number of 64 byte copy loop iterations
#else
srwi. r11, r7, 6 ! number of 64 byte copy loop iterations
#endif
addi r5, r8, 32 ! extra source pointer to avoid AGI delays
addi r6, r9, 32 ! extra destination pointer to avoid AGI delays
bc BO_IF, CR0_EQ, .L.residueBlock
mtctr r11 ! first/last (alone in group) on P6
.L.qWordLoop_dp:
lfd fp8, 0(r8) ! group 1
lfd fp9, 8(r8)
.long 0xf5090000 ! stfdp fp8, 0(r9) ! group 2
! 32-byte I-cache sector boundary (group start forced on DD3)
lfd fp10, 16(r8) ! group 3
lfd fp11, 24(r8)
addi r8, r8, 64 ! 3 cycles to next load use of r8
.long 0xf5490010 ! stfdp fp10, 16(r9) ! group 4
addi r9, r9, 64 ! 3 cycles to next store use of r9
lfd fp8, 0(r5) ! group 5
lfd fp9, 8(r5)
.long 0xf5060000 ! stfdp fp8, 0(r6) ! group 6
! 32-byte I-cache sector boundary (group start forced on DD3)
lfd fp10, 16(r5) ! group 7
lfd fp11, 24(r5)
addi r5, r5, 64 ! 3 cycles to next load use of r5
.long 0xf5460010 ! stfdp fp10, 16(r6) ! group 8
addi r6, r6, 64 ! 3 cycles to next store use of r6
bdnz .L.qWordLoop_dp ! 1/cycle, no grouping restriction
.L.residueBlock:
andi. r11, r7, 32 ! 32-byte residue block?
bc BO_IF, CR0_EQ, .L.over
lfd fp8, 0(r8)
lfd fp9, 8(r8)
.long 0xf5090000 ! stfdp fp8, 0(r9)
lfd fp10, 16(r8)
lfd fp11, 24(r8)
addi r8, r8, 32
.long 0xf5490010 ! stfdp fp10, 16(r9)
addi r9, r9, 32
.L.over:
andi. r7, r7, 31 ! residue bytes
bclr BO_IF, CR0_EQ
b .L.tableDispatch
.L.sourceMisaligned_dp:
.L.testOddAddressedSourceMisaligned_dp:
andi. r11, r8, 1 ! source aligned on PPC
bc BO_IF, CR0_EQ, .L.testHalfWordAlignSourceMisaligned_dp
lbz r11, 0(r8)
addi r8, r8, 1
addi r7, r7, -1
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stb r11, 0(r9)
addi r9, r9, 1
bc BO_IF, CR0_LT, .L.tableDispatch
.L.testHalfWordAlignSourceMisaligned_dp:
andi. r11, r8, 2
bc BO_IF, CR0_EQ, .L.continueSourceMisaligned_dp
lhz r11, 0(r8)
addi r7, r7, -2
addi r8, r8, 2
cmpli cr0, CmpAddr, r7, LONG_LENGTH
sth r11, 0(r9)
addi r9, r9, 2
bc BO_IF, CR0_LT, .L.tableDispatch
.L.continueSourceMisaligned_dp:
#ifdef TR_HOST_64BIT
! Making source 8 byte aligned for 64-bit environment
andi. r11, r8, 4
bc BO_IF, CR0_EQ, .L.continueSourceMisalignedLoop_dp
lwz r11, 0(r8)
addi r7, r7, -4
addi r8, r8, 4
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stw r11, 0(r9)
addi r9, r9, 4
bc BO_IF, CR0_LT, .L.tableDispatch
.L.continueSourceMisalignedLoop_dp:
! use doubleword loads and stores for the copy
srdi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11 ! first/last (alone in group) on P6
.L.dWordLoop_dp:
ld r6, 0(r8)
ld r5, 8(r8)
std r6, 0(r9)
std r5, 8(r9)
ld r0, 16(r8)
ld r11, 24(r8)
addi r8, r8, 32
std r0, 16(r9)
std r11, 24(r9)
addi r9, r9, 32
bdnz .L.dWordLoop_dp
bclr BO_IF, CR0_EQ
b .L.tableDispatch
#else
! use word loads and stores for the copy
srwi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11 ! first/last (alone in group) on P6
.L.wordLoop_dp:
lwz r6, 0(r8)
lwz r5, 4(r8)
stw r6, 0(r9)
stw r5, 4(r9)
lwz r0, 8(r8)
lwz r11, 12(r8)
stw r0, 8(r9)
stw r11, 12(r9)
lwz r6, 16(r8)
lwz r5, 20(r8)
stw r6, 16(r9)
stw r5, 20(r9)
lwz r0, 24(r8)
lwz r11, 28(r8)
addi r8, r8, 32
stw r0, 24(r9)
stw r11, 28(r9)
addi r9, r9, 32
bdnz .L.wordLoop_dp
bclr BO_IF, CR0_EQ
b .L.tableDispatch
#endif
.L.reverseArrayCopy_dp:
add r8, r8, r7
add r9, r9, r7
andi. r11, r9, 1
bc BO_IF, CR0_EQ, .L.testReverseHalfWordAlign_dp
lbz r11, -1(r8)
addi r8, r8, -1
addi r7, r7, -1
stb r11, -1(r9)
addi r9, r9, -1
.L.testReverseHalfWordAlign_dp:
andi. r11, r9, 2
bc BO_IF, CR0_EQ, .L.reverseWordAligned_dp
lhz r11, -2(r8)
addi r8, r8, -2
addi r7, r7, -2
cmpli cr0, CmpAddr, r7, LONG_LENGTH
sth r11, -2(r9)
addi r9, r9, -2
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.reverseWordAligned_dp:
! On a P6 processor stores that cross an 8B boundary cause two store
! operations from the core to the GPS, and that will cause a slowdown if
! the store queue becomes full.
andi. r11, r9, 4
bc BO_IF, CR0_EQ, .L.reverseDWordAligned_dp
lwz r11, -4(r8)
addi r8, r8, -4
addi r7, r7, -4
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stw r11, -4(r9)
addi r9, r9, -4
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.reverseDWordAligned_dp:
! Destination is doubleword (8-byte) aligned.
! On a P6 processor a floating point load/store that is not word aligned
! will take an alignment interrupt. If the source is not word aligned, fall
! back on using fixed point doubleword loads/stores.
andi. r11, r8, 7
bc BO_IF_NOT, CR0_EQ, .L.reverseSourceMisaligned_dp
! To use stfdp we need to align the destination on a 16-byte boundary.
andi. r11, r9, 8
bc BO_IF, CR0_EQ, .L.reverseQWordAligned_dp
lfd fp8, -8(r8)
addi r8, r8, -8
addi r7, r7, -8
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stfd fp8, -8(r9)
addi r9, r9, -8
bc BO_IF, CR0_LT, .L.reverseTableDispatch
#if defined(AIXPPC) || defined(LINUX) || defined(LINUXPPC64)
.align 5 ! force 32-byte I-cache sector alignment here
#endif
.L.reverseQWordAligned_dp:
#ifdef TR_HOST_64BIT
srdi. r11, r7, 6 ! number of 64 byte copy loop iterations
#else
srwi. r11, r7, 6 ! number of 64 byte copy loop iterations
#endif
addi r5, r8, -32 ! extra source pointer to avoid AGI delays
addi r6, r9, -32 ! extra destination pointer to avoid AGI delays
bc BO_IF, CR0_EQ, .L.reverseResidueBlock
mtctr r11 ! first/last (alone in group) on P6
.L.reverseQWordLoop_dp:
lfd fp9, -8(r8) ! group 1
lfd fp8, -16(r8)
.long 0xf509fff0 ! stfdp fp8, -16(r9) ! group 2
! 32-byte I-cache sector boundary (group start forced on DD3)
lfd fp11, -24(r8) ! group 3
lfd fp10, -32(r8)
addi r8, r8, -64 ! 3 cycles to next load use of r8
.long 0xf549ffe0 ! stfdp fp10, -32(r9) ! group 4
addi r9, r9, -64 ! 3 cycles to next store use of r9
lfd fp9, -8(r5) ! group 5
lfd fp8, -16(r5)
.long 0xf506fff0 ! stfdp fp8, -16(r6) ! group 6
! 32-byte I-cache sector boundary (group start forced on DD3)
lfd fp11, -24(r5) ! group 7
lfd fp10, -32(r5)
addi r5, r5, -64 ! 3 cycles to next load use of r5
.long 0xf546ffe0 ! stfdp fp10, -32(r6) ! group 8
addi r6, r6, -64 ! 3 cycles to next store use of r6
bdnz .L.reverseQWordLoop_dp ! 1/cycle, no grouping restriction
.L.reverseResidueBlock:
andi. r11, r7, 32 ! 32-byte residue block?
bc BO_IF, CR0_EQ, .L.reverseOver
lfd fp9, -8(r8)
lfd fp8, -16(r8)
.long 0xf509fff0 ! stfdp fp8, -16(r9)
lfd fp11, -24(r8)
lfd fp10, -32(r8)
addi r8, r8, -32
.long 0xf549ffe0 ! stfdp fp10, -32(r9)
addi r9, r9, -32
.L.reverseOver:
andi. r7, r7, 31 ! residue bytes
bclr BO_IF, CR0_EQ
b .L.reverseTableDispatch
.L.reverseSourceMisaligned_dp:
.L.reverseTestOddAddressedSourceMisaligned_dp:
andi. r11, r8, 1 ! source aligned on PPC
bc BO_IF, CR0_EQ, .L.reverseTestHalfWordAlignSourceMisaligned_dp
lbz r11, -1(r8)
addi r8, r8, -1
addi r7, r7, -1
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stb r11, -1(r9)
addi r9, r9, -1
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.reverseTestHalfWordAlignSourceMisaligned_dp:
andi. r11, r8, 2
bc BO_IF, CR0_EQ, .L.continueReverseSourceMisaligned_dp
lhz r11, -2(r8)
addi r8, r8, -2
addi r7, r7, -2
cmpli cr0, CmpAddr, r7, LONG_LENGTH
sth r11, -2(r9)
addi r9, r9, -2
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.continueReverseSourceMisaligned_dp:
#ifdef TR_HOST_64BIT
! Making source 8 byte aligned for 64-bit environment
andi. r11, r8, 4
bc BO_IF, CR0_EQ, .L.continueReverseSourceMisalignedLoop_dp
lwz r11, -4(r8)
addi r7, r7, -4
addi r8, r8, -4
cmpli cr0, CmpAddr, r7, LONG_LENGTH
stw r11, -4(r9)
addi r9, r9, -4
bc BO_IF, CR0_LT, .L.reverseTableDispatch
.L.continueReverseSourceMisalignedLoop_dp:
! use doubleword loads and stores for the copy
srdi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11 ! first/last (alone in group) on P6
.L.reverseDWordLoop_dp:
ld r6, -8(r8)
ld r5, -16(r8)
std r6, -8(r9)
std r5, -16(r9)
ld r0, -24(r8)
ld r11, -32(r8)
addi r8, r8, -32
std r0, -24(r9)
std r11, -32(r9)
addi r9, r9, -32
bdnz .L.reverseDWordLoop_dp
bclr BO_IF, CR0_EQ
b .L.reverseTableDispatch
#else
! use word loads and stores for the copy
srwi r11, r7, 5 ! number of loop iterations
andi. r7, r7, 31 ! residue bytes
mtctr r11 ! first/last (alone in group) on P6
.L.reverseWordLoop_dp:
lwz r6, -4(r8)
lwz r5, -8(r8)
stw r6, -4(r9)
stw r5, -8(r9)
lwz r0, -12(r8)
lwz r11, -16(r8)
stw r0, -12(r9)
stw r11, -16(r9)
lwz r6, -20(r8)
lwz r5, -24(r8)
stw r6, -20(r9)
stw r5, -24(r9)
lwz r0, -28(r8)
lwz r11, -32(r8)
addi r8, r8, -32
stw r0, -28(r9)
stw r11, -32(r9)
addi r9, r9, -32
bdnz .L.reverseWordLoop_dp
bclr BO_IF, CR0_EQ
b .L.reverseTableDispatch
#endif
endproc.__arrayCopy_dp:
#ifdef AIXPPC
.csect __wordArrayCopy_dp{PR}
.__wordArrayCopy_dp:
.function .__wordArrayCopy_dp,startproc.__wordArrayCopy_dp,16,0,(endproc.__wordArrayCopy_dp-startproc.__wordArrayCopy_dp)
#elif defined(LINUXPPC64)
FUNC_LABEL(__wordArrayCopy_dp):
#else
__wordArrayCopy_dp:
#endif
startproc.__wordArrayCopy_dp:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
subf r11, r8, r9
bc BO_IF, CR0_LT, .L.tableDispatch
cmpl cr0, CmpAddr, r11, r7
bc BO_IF_NOT, CR0_LT, .L.wordAligned_dp
add r8, r8, r7
add r9, r9, r7
b .L.reverseWordAligned_dp
endproc.__wordArrayCopy_dp:
#ifdef AIXPPC
.csect __halfWordArrayCopy_dp{PR}
.__halfWordArrayCopy_dp:
.function .__halfWordArrayCopy_dp,startproc.__halfWordArrayCopy_dp,16,0,(endproc.__halfWordArrayCopy_dp-startproc.__halfWordArrayCopy_dp)
#elif defined(LINUXPPC64)
FUNC_LABEL(__halfWordArrayCopy_dp):
#else
__halfWordArrayCopy_dp:
#endif
startproc.__halfWordArrayCopy_dp:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
subf r11, r8, r9
bc BO_IF, CR0_LT, .L.tableDispatch
cmpl cr0, CmpAddr, r11, r7
bc BO_IF_NOT, CR0_LT, .L.testHalfWordAlign_dp
add r8, r8, r7
add r9, r9, r7
b .L.testReverseHalfWordAlign_dp
endproc.__halfWordArrayCopy_dp:
#ifdef AIXPPC
.csect __forwardArrayCopy_dp{PR}
.__forwardArrayCopy_dp:
.function .__forwardArrayCopy_dp,startproc.__forwardArrayCopy_dp,16,0,(endproc.__forwardArrayCopy_dp-startproc.__forwardArrayCopy_dp)
#elif defined(LINUXPPC64)
FUNC_LABEL(__forwardArrayCopy_dp):
#else
__forwardArrayCopy_dp:
#endif
startproc.__forwardArrayCopy_dp:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
bc BO_IF, CR0_LT, .L.tableDispatch
b .L.testOddAddressed_dp
endproc.__forwardArrayCopy_dp:
#ifdef AIXPPC
.csect __forwardArrayCopy_dp{PR}
.__forwardWordArrayCopy_dp:
.function .__forwardWordArrayCopy_dp,startproc.__forwardWordArrayCopy_dp,16,0,(endproc.__forwardWordArrayCopy_dp-startproc.__forwardWordArrayCopy_dp)
#elif defined(LINUXPPC64)
FUNC_LABEL(__forwardWordArrayCopy_dp):
#else
__forwardWordArrayCopy_dp:
#endif
startproc.__forwardWordArrayCopy_dp:
cmpli cr0, CmpAddr, r7, LONG_LENGTH
bc BO_IF, CR0_LT, .L.tableDispatch
b .L.wordAligned_dp
endproc.__forwardWordArrayCopy_dp:
#ifdef AIXPPC
.csect __forwardHalfWordArrayCopy_dp{PR}, 5
.__forwardHalfWordArrayCopy_dp:
.function .__forwardHalfWordArrayCopy_dp,startproc.__forwardHalfWordArrayCopy_dp,16,0,(endproc.__forwardHalfWordArrayCopy_dp-startproc.__forwardHalfWordArrayCopy_dp)
#elif defined(LINUXPPC64)
FUNC_LABEL(__forwardHalfWordArrayCopy_dp):
#else
__forwardHalfWordArrayCopy_dp:
#endif
startproc.__forwardHalfWordArrayCopy_dp:
dcbt r0, r8
dcbtst r0, r9
cmpli cr0, CmpAddr, r7, LONG_LENGTH
bc BO_IF_NOT, CR0_LT, .L.testHalfWordAlign_dp
laddr r11, J9TR_VMThreadRTOCOffset(J9VM_STRUCT) ! Restore TOC/GOT
#ifdef TR_HOST_64BIT
rlwinm r7, r7, 3, 0xFFFFFFF8
#else
rlwinm r7, r7, 2, 0xFFFFFFFC
#endif
#ifdef AIXPPC
laddr r11, TOC__shortArrayCopyLabelTable(r11)
#elif defined(LINUXPPC64)
laddr r11, TOC__shortArrayCopyLabelTable@toc(r11)
#else
laddr r11, __shortArrayCopyLabelTable@got(r11)
#endif
laddrx r11, r11, r7
mtctr r11
bctr
endproc.__forwardHalfWordArrayCopy_dp:
#ifdef AIXPPC
.csect __codeForShortArrayCopy{PR}