-
-
Notifications
You must be signed in to change notification settings - Fork 213
/
Copy pathabstractodesystem.jl
1413 lines (1261 loc) · 50.3 KB
/
abstractodesystem.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
struct Schedule
var_eq_matching::Any
dummy_sub::Any
end
"""
is_dde(sys::AbstractSystem)
Return a boolean indicating whether a system represents a set of delay
differential equations.
"""
is_dde(sys::AbstractSystem) = has_is_dde(sys) && get_is_dde(sys)
function _check_if_dde(eqs, iv, subsystems)
is_dde = any(ModelingToolkit.is_dde, subsystems)
if !is_dde
vs = Set()
for eq in eqs
vars!(vs, eq)
is_dde = any(vs) do sym
isdelay(unwrap(sym), iv)
end
is_dde && break
end
end
return is_dde
end
function filter_kwargs(kwargs)
kwargs = Dict(kwargs)
for key in keys(kwargs)
key in DiffEqBase.allowedkeywords || delete!(kwargs, key)
end
pairs(NamedTuple(kwargs))
end
function gen_quoted_kwargs(kwargs)
kwargparam = Expr(:parameters)
for kw in kwargs
push!(kwargparam.args, Expr(:kw, kw[1], kw[2]))
end
kwargparam
end
function calculate_tgrad(sys::AbstractODESystem;
simplify = false)
isempty(get_tgrad(sys)[]) || return get_tgrad(sys)[] # use cached tgrad, if possible
# We need to remove explicit time dependence on the unknown because when we
# have `u(t) * t` we want to have the tgrad to be `u(t)` instead of `u'(t) *
# t + u(t)`.
rhs = [detime_dvs(eq.rhs) for eq in full_equations(sys)]
iv = get_iv(sys)
xs = unknowns(sys)
rule = Dict(map((x, xt) -> xt => x, detime_dvs.(xs), xs))
rhs = substitute.(rhs, Ref(rule))
tgrad = [expand_derivatives(Differential(iv)(r), simplify) for r in rhs]
reverse_rule = Dict(map((x, xt) -> x => xt, detime_dvs.(xs), xs))
tgrad = Num.(substitute.(tgrad, Ref(reverse_rule)))
get_tgrad(sys)[] = tgrad
return tgrad
end
function calculate_jacobian(sys::AbstractODESystem;
sparse = false, simplify = false, dvs = unknowns(sys))
if isequal(dvs, unknowns(sys))
cache = get_jac(sys)[]
if cache isa Tuple && cache[2] == (sparse, simplify)
return cache[1]
end
end
rhs = [eq.rhs - eq.lhs for eq in full_equations(sys)] #need du terms on rhs for differentiating wrt du
if sparse
jac = sparsejacobian(rhs, dvs, simplify = simplify)
else
jac = jacobian(rhs, dvs, simplify = simplify)
end
if isequal(dvs, unknowns(sys))
get_jac(sys)[] = jac, (sparse, simplify) # cache Jacobian
end
return jac
end
function calculate_control_jacobian(sys::AbstractODESystem;
sparse = false, simplify = false)
cache = get_ctrl_jac(sys)[]
if cache isa Tuple && cache[2] == (sparse, simplify)
return cache[1]
end
rhs = [eq.rhs for eq in full_equations(sys)]
ctrls = controls(sys)
if sparse
jac = sparsejacobian(rhs, ctrls, simplify = simplify)
else
jac = jacobian(rhs, ctrls, simplify = simplify)
end
get_ctrl_jac(sys)[] = jac, (sparse, simplify) # cache Jacobian
return jac
end
function generate_tgrad(
sys::AbstractODESystem, dvs = unknowns(sys), ps = parameters(sys);
simplify = false, wrap_code = identity, kwargs...)
tgrad = calculate_tgrad(sys, simplify = simplify)
pre = get_preprocess_constants(tgrad)
p = if has_index_cache(sys) && get_index_cache(sys) !== nothing
reorder_parameters(get_index_cache(sys), ps)
elseif ps isa Tuple
ps
else
(ps,)
end
wrap_code = wrap_code .∘ wrap_array_vars(sys, tgrad; dvs, ps) .∘
wrap_parameter_dependencies(sys, !(tgrad isa AbstractArray))
return build_function(tgrad,
dvs,
p...,
get_iv(sys);
postprocess_fbody = pre,
wrap_code,
kwargs...)
end
function generate_jacobian(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys);
simplify = false, sparse = false, wrap_code = identity, kwargs...)
jac = calculate_jacobian(sys; simplify = simplify, sparse = sparse)
pre = get_preprocess_constants(jac)
p = if has_index_cache(sys) && get_index_cache(sys) !== nothing
reorder_parameters(get_index_cache(sys), ps)
else
(ps,)
end
wrap_code = wrap_code .∘ wrap_array_vars(sys, jac; dvs, ps) .∘
wrap_parameter_dependencies(sys, false)
return build_function(jac,
dvs,
p...,
get_iv(sys);
postprocess_fbody = pre,
wrap_code,
kwargs...)
end
function generate_control_jacobian(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys);
simplify = false, sparse = false, kwargs...)
jac = calculate_control_jacobian(sys; simplify = simplify, sparse = sparse)
p = reorder_parameters(sys, ps)
return build_function(jac, dvs, p..., get_iv(sys); kwargs...)
end
function generate_dae_jacobian(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys); simplify = false, sparse = false,
kwargs...)
jac_u = calculate_jacobian(sys; simplify = simplify, sparse = sparse)
derivatives = Differential(get_iv(sys)).(unknowns(sys))
jac_du = calculate_jacobian(sys; simplify = simplify, sparse = sparse,
dvs = derivatives)
dvs = unknowns(sys)
@variables ˍ₋gamma
jac = ˍ₋gamma * jac_du + jac_u
pre = get_preprocess_constants(jac)
p = if has_index_cache(sys) && get_index_cache(sys) !== nothing
reorder_parameters(get_index_cache(sys), ps)
else
(ps,)
end
return build_function(jac, derivatives, dvs, p..., ˍ₋gamma, get_iv(sys);
postprocess_fbody = pre, kwargs...)
end
function generate_function(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys);
implicit_dae = false,
ddvs = implicit_dae ? map(Differential(get_iv(sys)), dvs) :
nothing,
isdde = false,
wrap_code = identity,
kwargs...)
if isdde
issplit = has_index_cache(sys) && get_index_cache(sys) !== nothing
eqs = delay_to_function(
sys; history_arg = issplit ? MTKPARAMETERS_ARG : DEFAULT_PARAMS_ARG)
else
eqs = [eq for eq in equations(sys)]
end
if !implicit_dae
check_operator_variables(eqs, Differential)
check_lhs(eqs, Differential, Set(dvs))
end
# substitute constants in
eqs = map(subs_constants, eqs)
# substitute x(t) by just x
rhss = implicit_dae ? [_iszero(eq.lhs) ? eq.rhs : eq.rhs - eq.lhs for eq in eqs] :
[eq.rhs for eq in eqs]
# TODO: add an optional check on the ordering of observed equations
u = map(x -> time_varying_as_func(value(x), sys), dvs)
p = map.(x -> time_varying_as_func(value(x), sys), reorder_parameters(sys, ps))
t = get_iv(sys)
if isdde
build_function(rhss, u, DDE_HISTORY_FUN, p..., t; kwargs...,
wrap_code = wrap_code .∘ wrap_mtkparameters(sys, false, 3) .∘
wrap_array_vars(sys, rhss; dvs, ps, history = true) .∘
wrap_parameter_dependencies(sys, false))
else
pre, sol_states = get_substitutions_and_solved_unknowns(sys)
if implicit_dae
# inputs = [] makes `wrap_array_vars` offset by 1 since there is an extra
# argument
build_function(rhss, ddvs, u, p..., t; postprocess_fbody = pre,
states = sol_states,
wrap_code = wrap_code .∘ wrap_array_vars(sys, rhss; dvs, ps, inputs = []) .∘
wrap_parameter_dependencies(sys, false),
kwargs...)
else
build_function(rhss, u, p..., t; postprocess_fbody = pre,
states = sol_states,
wrap_code = wrap_code .∘ wrap_array_vars(sys, rhss; dvs, ps) .∘
wrap_parameter_dependencies(sys, false),
kwargs...)
end
end
end
function isdelay(var, iv)
iv === nothing && return false
isvariable(var) || return false
if iscall(var) && !ModelingToolkit.isoperator(var, Symbolics.Operator)
args = arguments(var)
length(args) == 1 || return false
isequal(args[1], iv) || return true
end
return false
end
const DDE_HISTORY_FUN = Sym{Symbolics.FnType{Tuple{Any, <:Real}, Vector{Real}}}(:___history___)
const DEFAULT_PARAMS_ARG = Sym{Any}(:ˍ₋arg3)
function delay_to_function(
sys::AbstractODESystem, eqs = full_equations(sys); history_arg = DEFAULT_PARAMS_ARG)
delay_to_function(eqs,
get_iv(sys),
Dict{Any, Int}(operation(s) => i for (i, s) in enumerate(unknowns(sys))),
parameters(sys),
DDE_HISTORY_FUN; history_arg)
end
function delay_to_function(eqs::Vector, iv, sts, ps, h; history_arg = DEFAULT_PARAMS_ARG)
delay_to_function.(eqs, (iv,), (sts,), (ps,), (h,); history_arg)
end
function delay_to_function(eq::Equation, iv, sts, ps, h; history_arg = DEFAULT_PARAMS_ARG)
delay_to_function(eq.lhs, iv, sts, ps, h; history_arg) ~ delay_to_function(
eq.rhs, iv, sts, ps, h; history_arg)
end
function delay_to_function(expr, iv, sts, ps, h; history_arg = DEFAULT_PARAMS_ARG)
if isdelay(expr, iv)
v = operation(expr)
time = arguments(expr)[1]
idx = sts[v]
return term(getindex, h(history_arg, time), idx, type = Real) # BIG BIG HACK
elseif iscall(expr)
return maketerm(typeof(expr),
operation(expr),
map(x -> delay_to_function(x, iv, sts, ps, h; history_arg), arguments(expr)),
metadata(expr))
else
return expr
end
end
function calculate_massmatrix(sys::AbstractODESystem; simplify = false)
eqs = [eq for eq in equations(sys)]
M = zeros(length(eqs), length(eqs))
for (i, eq) in enumerate(eqs)
if iscall(eq.lhs) && operation(eq.lhs) isa Differential
st = var_from_nested_derivative(eq.lhs)[1]
j = variable_index(sys, st)
M[i, j] = 1
else
_iszero(eq.lhs) ||
error("Only semi-explicit constant mass matrices are currently supported. Faulty equation: $eq.")
end
end
M = simplify ? ModelingToolkit.simplify.(M) : M
# M should only contain concrete numbers
M == I ? I : M
end
function jacobian_sparsity(sys::AbstractODESystem)
sparsity = torn_system_jacobian_sparsity(sys)
sparsity === nothing || return sparsity
jacobian_sparsity([eq.rhs for eq in full_equations(sys)],
[dv for dv in unknowns(sys)])
end
function jacobian_dae_sparsity(sys::AbstractODESystem)
J1 = jacobian_sparsity([eq.rhs for eq in full_equations(sys)],
[dv for dv in unknowns(sys)])
derivatives = Differential(get_iv(sys)).(unknowns(sys))
J2 = jacobian_sparsity([eq.rhs for eq in full_equations(sys)],
[dv for dv in derivatives])
J1 + J2
end
function isautonomous(sys::AbstractODESystem)
tgrad = calculate_tgrad(sys; simplify = true)
all(iszero, tgrad)
end
"""
```julia
DiffEqBase.ODEFunction{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys);
version = nothing, tgrad = false,
jac = false,
sparse = false,
kwargs...) where {iip}
```
Create an `ODEFunction` from the [`ODESystem`](@ref). The arguments `dvs` and `ps`
are used to set the order of the dependent variable and parameter vectors,
respectively.
"""
function DiffEqBase.ODEFunction(sys::AbstractODESystem, args...; kwargs...)
ODEFunction{true}(sys, args...; kwargs...)
end
function DiffEqBase.ODEFunction{true}(sys::AbstractODESystem, args...;
kwargs...)
ODEFunction{true, SciMLBase.AutoSpecialize}(sys, args...; kwargs...)
end
function DiffEqBase.ODEFunction{false}(sys::AbstractODESystem, args...;
kwargs...)
ODEFunction{false, SciMLBase.FullSpecialize}(sys, args...; kwargs...)
end
function DiffEqBase.ODEFunction{iip, specialize}(sys::AbstractODESystem,
dvs = unknowns(sys),
ps = parameters(sys), u0 = nothing;
version = nothing, tgrad = false,
jac = false, p = nothing,
t = nothing,
eval_expression = false,
sparse = false, simplify = false,
eval_module = @__MODULE__,
steady_state = false,
checkbounds = false,
sparsity = false,
analytic = nothing,
split_idxs = nothing,
initialization_data = nothing,
kwargs...) where {iip, specialize}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating an `ODEFunction`")
end
f_gen = generate_function(sys, dvs, ps; expression = Val{true},
expression_module = eval_module, checkbounds = checkbounds,
kwargs...)
f_oop, f_iip = eval_or_rgf.(f_gen; eval_expression, eval_module)
f(u, p, t) = f_oop(u, p, t)
f(du, u, p, t) = f_iip(du, u, p, t)
f(u, p::Tuple{Vararg{Number}}, t) = f_oop(u, p, t)
f(du, u, p::Tuple{Vararg{Number}}, t) = f_iip(du, u, p, t)
f(u, p::Tuple, t) = f_oop(u, p..., t)
f(du, u, p::Tuple, t) = f_iip(du, u, p..., t)
f(u, p::MTKParameters, t) = f_oop(u, p..., t)
f(du, u, p::MTKParameters, t) = f_iip(du, u, p..., t)
if specialize === SciMLBase.FunctionWrapperSpecialize && iip
if u0 === nothing || p === nothing || t === nothing
error("u0, p, and t must be specified for FunctionWrapperSpecialize on ODEFunction.")
end
f = SciMLBase.wrapfun_iip(f, (u0, u0, p, t))
end
if tgrad
tgrad_gen = generate_tgrad(sys, dvs, ps;
simplify = simplify,
expression = Val{true},
expression_module = eval_module,
checkbounds = checkbounds, kwargs...)
tgrad_oop, tgrad_iip = eval_or_rgf.(tgrad_gen; eval_expression, eval_module)
if p isa Tuple
__tgrad(u, p, t) = tgrad_oop(u, p..., t)
__tgrad(J, u, p, t) = tgrad_iip(J, u, p..., t)
_tgrad = __tgrad
else
___tgrad(u, p, t) = tgrad_oop(u, p, t)
___tgrad(J, u, p, t) = tgrad_iip(J, u, p, t)
_tgrad = ___tgrad
end
else
_tgrad = nothing
end
if jac
jac_gen = generate_jacobian(sys, dvs, ps;
simplify = simplify, sparse = sparse,
expression = Val{true},
expression_module = eval_module,
checkbounds = checkbounds, kwargs...)
jac_oop, jac_iip = eval_or_rgf.(jac_gen; eval_expression, eval_module)
_jac(u, p, t) = jac_oop(u, p, t)
_jac(J, u, p, t) = jac_iip(J, u, p, t)
_jac(u, p::Tuple{Vararg{Number}}, t) = jac_oop(u, p, t)
_jac(J, u, p::Tuple{Vararg{Number}}, t) = jac_iip(J, u, p, t)
_jac(u, p::Tuple, t) = jac_oop(u, p..., t)
_jac(J, u, p::Tuple, t) = jac_iip(J, u, p..., t)
_jac(u, p::MTKParameters, t) = jac_oop(u, p..., t)
_jac(J, u, p::MTKParameters, t) = jac_iip(J, u, p..., t)
else
_jac = nothing
end
M = calculate_massmatrix(sys)
_M = if sparse && !(u0 === nothing || M === I)
SparseArrays.sparse(M)
elseif u0 === nothing || M === I
M
else
ArrayInterface.restructure(u0 .* u0', M)
end
observedfun = ObservedFunctionCache(
sys; steady_state, eval_expression, eval_module, checkbounds)
jac_prototype = if sparse
uElType = u0 === nothing ? Float64 : eltype(u0)
if jac
similar(calculate_jacobian(sys, sparse = sparse), uElType)
else
similar(jacobian_sparsity(sys), uElType)
end
else
nothing
end
@set! sys.split_idxs = split_idxs
ODEFunction{iip, specialize}(f;
sys = sys,
jac = _jac === nothing ? nothing : _jac,
tgrad = _tgrad === nothing ? nothing : _tgrad,
mass_matrix = _M,
jac_prototype = jac_prototype,
observed = observedfun,
sparsity = sparsity ? jacobian_sparsity(sys) : nothing,
analytic = analytic,
initialization_data)
end
"""
```julia
DiffEqBase.DAEFunction{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys);
version = nothing, tgrad = false,
jac = false,
sparse = false,
kwargs...) where {iip}
```
Create an `DAEFunction` from the [`ODESystem`](@ref). The arguments `dvs` and
`ps` are used to set the order of the dependent variable and parameter vectors,
respectively.
"""
function DiffEqBase.DAEFunction(sys::AbstractODESystem, args...; kwargs...)
DAEFunction{true}(sys, args...; kwargs...)
end
function DiffEqBase.DAEFunction{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys), u0 = nothing;
ddvs = map(Base.Fix2(diff2term, get_iv(sys)) ∘ Differential(get_iv(sys)), dvs),
version = nothing, p = nothing,
jac = false,
eval_expression = false,
sparse = false, simplify = false,
eval_module = @__MODULE__,
checkbounds = false,
initialization_data = nothing,
kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating a `DAEFunction`")
end
f_gen = generate_function(sys, dvs, ps; implicit_dae = true,
expression = Val{true},
expression_module = eval_module, checkbounds = checkbounds,
kwargs...)
f_oop, f_iip = eval_or_rgf.(f_gen; eval_expression, eval_module)
f(du, u, p, t) = f_oop(du, u, p, t)
f(du, u, p::MTKParameters, t) = f_oop(du, u, p..., t)
f(out, du, u, p, t) = f_iip(out, du, u, p, t)
f(out, du, u, p::MTKParameters, t) = f_iip(out, du, u, p..., t)
if jac
jac_gen = generate_dae_jacobian(sys, dvs, ps;
simplify = simplify, sparse = sparse,
expression = Val{true},
expression_module = eval_module,
checkbounds = checkbounds, kwargs...)
jac_oop, jac_iip = eval_or_rgf.(jac_gen; eval_expression, eval_module)
_jac(du, u, p, ˍ₋gamma, t) = jac_oop(du, u, p, ˍ₋gamma, t)
_jac(du, u, p::MTKParameters, ˍ₋gamma, t) = jac_oop(du, u, p..., ˍ₋gamma, t)
_jac(J, du, u, p, ˍ₋gamma, t) = jac_iip(J, du, u, p, ˍ₋gamma, t)
_jac(J, du, u, p::MTKParameters, ˍ₋gamma, t) = jac_iip(J, du, u, p..., ˍ₋gamma, t)
else
_jac = nothing
end
observedfun = ObservedFunctionCache(
sys; eval_expression, eval_module, checkbounds = get(kwargs, :checkbounds, false))
jac_prototype = if sparse
uElType = u0 === nothing ? Float64 : eltype(u0)
if jac
J1 = calculate_jacobian(sys, sparse = sparse)
derivatives = Differential(get_iv(sys)).(unknowns(sys))
J2 = calculate_jacobian(sys; sparse = sparse, dvs = derivatives)
similar(J1 + J2, uElType)
else
similar(jacobian_dae_sparsity(sys), uElType)
end
else
nothing
end
DAEFunction{iip}(f;
sys = sys,
jac = _jac === nothing ? nothing : _jac,
jac_prototype = jac_prototype,
observed = observedfun,
initialization_data)
end
function DiffEqBase.DDEFunction(sys::AbstractODESystem, args...; kwargs...)
DDEFunction{true}(sys, args...; kwargs...)
end
function DiffEqBase.DDEFunction{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys), u0 = nothing;
eval_expression = false,
eval_module = @__MODULE__,
checkbounds = false,
initialization_data = nothing,
kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating an `DDEFunction`")
end
f_gen = generate_function(sys, dvs, ps; isdde = true,
expression = Val{true},
expression_module = eval_module, checkbounds = checkbounds,
kwargs...)
f_oop, f_iip = eval_or_rgf.(f_gen; eval_expression, eval_module)
f(u, h, p, t) = f_oop(u, h, p, t)
f(du, u, h, p, t) = f_iip(du, u, h, p, t)
DDEFunction{iip}(f; sys = sys, initialization_data)
end
function DiffEqBase.SDDEFunction(sys::AbstractODESystem, args...; kwargs...)
SDDEFunction{true}(sys, args...; kwargs...)
end
function DiffEqBase.SDDEFunction{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys), u0 = nothing;
eval_expression = false,
eval_module = @__MODULE__,
checkbounds = false,
initialization_data = nothing,
kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating an `SDDEFunction`")
end
f_gen = generate_function(sys, dvs, ps; isdde = true,
expression = Val{true},
expression_module = eval_module, checkbounds = checkbounds,
kwargs...)
f_oop, f_iip = eval_or_rgf.(f_gen; eval_expression, eval_module)
f(u, h, p, t) = f_oop(u, h, p, t)
f(du, u, h, p, t) = f_iip(du, u, h, p, t)
g_gen = generate_diffusion_function(sys, dvs, ps; expression = Val{true},
isdde = true, kwargs...)
g_oop, g_iip = eval_or_rgf.(g_gen; eval_expression, eval_module)
g(u, h, p, t) = g_oop(u, h, p, t)
g(du, u, h, p, t) = g_iip(du, u, h, p, t)
SDDEFunction{iip}(f, g; sys = sys, initialization_data)
end
"""
```julia
ODEFunctionExpr{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys);
version = nothing, tgrad = false,
jac = false,
sparse = false,
kwargs...) where {iip}
```
Create a Julia expression for an `ODEFunction` from the [`ODESystem`](@ref).
The arguments `dvs` and `ps` are used to set the order of the dependent
variable and parameter vectors, respectively.
"""
struct ODEFunctionExpr{iip} end
struct ODEFunctionClosure{O, I} <: Function
f_oop::O
f_iip::I
end
(f::ODEFunctionClosure)(u, p, t) = f.f_oop(u, p, t)
(f::ODEFunctionClosure)(du, u, p, t) = f.f_iip(du, u, p, t)
(f::ODEFunctionClosure)(u, p::MTKParameters, t) = f.f_oop(u, p..., t)
(f::ODEFunctionClosure)(du, u, p::MTKParameters, t) = f.f_iip(du, u, p..., t)
function ODEFunctionExpr{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys), u0 = nothing;
version = nothing, tgrad = false,
jac = false, p = nothing,
linenumbers = false,
sparse = false, simplify = false,
steady_state = false,
sparsity = false,
observedfun_exp = nothing,
kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating an `ODEFunctionExpr`")
end
f_oop, f_iip = generate_function(sys, dvs, ps; expression = Val{true}, kwargs...)
dict = Dict()
fsym = gensym(:f)
_f = :($fsym = $ODEFunctionClosure($f_oop, $f_iip))
tgradsym = gensym(:tgrad)
if tgrad
tgrad_oop, tgrad_iip = generate_tgrad(sys, dvs, ps;
simplify = simplify,
expression = Val{true}, kwargs...)
_tgrad = :($tgradsym = $ODEFunctionClosure($tgrad_oop, $tgrad_iip))
else
_tgrad = :($tgradsym = nothing)
end
jacsym = gensym(:jac)
if jac
jac_oop, jac_iip = generate_jacobian(sys, dvs, ps;
sparse = sparse, simplify = simplify,
expression = Val{true}, kwargs...)
_jac = :($jacsym = $ODEFunctionClosure($jac_oop, $jac_iip))
else
_jac = :($jacsym = nothing)
end
M = calculate_massmatrix(sys)
_M = if sparse && !(u0 === nothing || M === I)
SparseArrays.sparse(M)
elseif u0 === nothing || M === I
M
else
ArrayInterface.restructure(u0 .* u0', M)
end
jp_expr = sparse ? :($similar($(get_jac(sys)[]), Float64)) : :nothing
ex = quote
$_f
$_tgrad
$_jac
M = $_M
ODEFunction{$iip}($fsym,
sys = $sys,
jac = $jacsym,
tgrad = $tgradsym,
mass_matrix = M,
jac_prototype = $jp_expr,
sparsity = $(sparsity ? jacobian_sparsity(sys) : nothing),
observed = $observedfun_exp)
end
!linenumbers ? Base.remove_linenums!(ex) : ex
end
function ODEFunctionExpr(sys::AbstractODESystem, args...; kwargs...)
ODEFunctionExpr{true}(sys, args...; kwargs...)
end
"""
```julia
DAEFunctionExpr{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys);
version = nothing, tgrad = false,
jac = false,
sparse = false,
kwargs...) where {iip}
```
Create a Julia expression for an `ODEFunction` from the [`ODESystem`](@ref).
The arguments `dvs` and `ps` are used to set the order of the dependent
variable and parameter vectors, respectively.
"""
struct DAEFunctionExpr{iip} end
struct DAEFunctionClosure{O, I} <: Function
f_oop::O
f_iip::I
end
(f::DAEFunctionClosure)(du, u, p, t) = f.f_oop(du, u, p, t)
(f::DAEFunctionClosure)(out, du, u, p, t) = f.f_iip(out, du, u, p, t)
(f::DAEFunctionClosure)(du, u, p::MTKParameters, t) = f.f_oop(du, u, p..., t)
(f::DAEFunctionClosure)(out, du, u, p::MTKParameters, t) = f.f_iip(out, du, u, p..., t)
function DAEFunctionExpr{iip}(sys::AbstractODESystem, dvs = unknowns(sys),
ps = parameters(sys), u0 = nothing;
version = nothing, tgrad = false,
jac = false, p = nothing,
linenumbers = false,
sparse = false, simplify = false,
kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating an `DAEFunctionExpr`")
end
f_oop, f_iip = generate_function(sys, dvs, ps; expression = Val{true},
implicit_dae = true, kwargs...)
fsym = gensym(:f)
_f = :($fsym = $DAEFunctionClosure($f_oop, $f_iip))
ex = quote
$_f
ODEFunction{$iip}($fsym)
end
!linenumbers ? Base.remove_linenums!(ex) : ex
end
function DAEFunctionExpr(sys::AbstractODESystem, args...; kwargs...)
DAEFunctionExpr{true}(sys, args...; kwargs...)
end
struct SymbolicTstops{F}
fn::F
end
function (st::SymbolicTstops)(p, tspan)
unique!(sort!(reduce(vcat, st.fn(p..., tspan...))))
end
function SymbolicTstops(
sys::AbstractSystem; eval_expression = false, eval_module = @__MODULE__)
tstops = symbolic_tstops(sys)
isempty(tstops) && return nothing
t0 = gensym(:t0)
t1 = gensym(:t1)
tstops = map(tstops) do val
if is_array_of_symbolics(val) || val isa AbstractArray
collect(val)
else
term(:, t0, unwrap(val), t1; type = AbstractArray{Real})
end
end
rps = reorder_parameters(sys, parameters(sys))
tstops, _ = build_function(tstops,
rps...,
t0,
t1;
expression = Val{true},
wrap_code = wrap_array_vars(sys, tstops; dvs = nothing) .∘
wrap_parameter_dependencies(sys, false))
tstops = eval_or_rgf(tstops; eval_expression, eval_module)
return SymbolicTstops(tstops)
end
"""
```julia
DiffEqBase.ODEProblem{iip}(sys::AbstractODESystem, u0map, tspan,
parammap = DiffEqBase.NullParameters();
version = nothing, tgrad = false,
jac = false,
checkbounds = false, sparse = false,
simplify = false,
linenumbers = true, parallel = SerialForm(),
kwargs...) where {iip}
```
Generates an ODEProblem from an ODESystem and allows for automatically
symbolically calculating numerical enhancements.
"""
function DiffEqBase.ODEProblem(sys::AbstractODESystem, args...; kwargs...)
ODEProblem{true}(sys, args...; kwargs...)
end
function DiffEqBase.ODEProblem(sys::AbstractODESystem,
u0map::StaticArray,
args...;
kwargs...)
ODEProblem{false, SciMLBase.FullSpecialize}(sys, u0map, args...; kwargs...)
end
function DiffEqBase.ODEProblem{true}(sys::AbstractODESystem, args...; kwargs...)
ODEProblem{true, SciMLBase.AutoSpecialize}(sys, args...; kwargs...)
end
function DiffEqBase.ODEProblem{false}(sys::AbstractODESystem, args...; kwargs...)
ODEProblem{false, SciMLBase.FullSpecialize}(sys, args...; kwargs...)
end
function DiffEqBase.ODEProblem{iip, specialize}(sys::AbstractODESystem, u0map = [],
tspan = get_tspan(sys),
parammap = DiffEqBase.NullParameters();
callback = nothing,
check_length = true,
warn_initialize_determined = true,
eval_expression = false,
eval_module = @__MODULE__,
kwargs...) where {iip, specialize}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating an `ODEProblem`")
end
f, u0, p = process_SciMLProblem(ODEFunction{iip, specialize}, sys, u0map, parammap;
t = tspan !== nothing ? tspan[1] : tspan,
check_length, warn_initialize_determined, eval_expression, eval_module, kwargs...)
cbs = process_events(sys; callback, eval_expression, eval_module, kwargs...)
kwargs = filter_kwargs(kwargs)
pt = something(get_metadata(sys), StandardODEProblem())
kwargs1 = (;)
if cbs !== nothing
kwargs1 = merge(kwargs1, (callback = cbs,))
end
tstops = SymbolicTstops(sys; eval_expression, eval_module)
if tstops !== nothing
kwargs1 = merge(kwargs1, (; tstops))
end
return ODEProblem{iip}(f, u0, tspan, p, pt; kwargs1..., kwargs...)
end
get_callback(prob::ODEProblem) = prob.kwargs[:callback]
"""
```julia
DiffEqBase.DAEProblem{iip}(sys::AbstractODESystem, du0map, u0map, tspan,
parammap = DiffEqBase.NullParameters();
version = nothing, tgrad = false,
jac = false,
checkbounds = false, sparse = false,
simplify = false,
linenumbers = true, parallel = SerialForm(),
kwargs...) where {iip}
```
Generates a DAEProblem from an ODESystem and allows for automatically
symbolically calculating numerical enhancements.
"""
function DiffEqBase.DAEProblem(sys::AbstractODESystem, args...; kwargs...)
DAEProblem{true}(sys, args...; kwargs...)
end
function DiffEqBase.DAEProblem{iip}(sys::AbstractODESystem, du0map, u0map, tspan,
parammap = DiffEqBase.NullParameters();
warn_initialize_determined = true,
check_length = true, eval_expression = false, eval_module = @__MODULE__, kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating a `DAEProblem`")
end
f, du0, u0, p = process_SciMLProblem(DAEFunction{iip}, sys, u0map, parammap;
implicit_dae = true, du0map = du0map, check_length,
t = tspan !== nothing ? tspan[1] : tspan,
warn_initialize_determined, kwargs...)
diffvars = collect_differential_variables(sys)
sts = unknowns(sys)
differential_vars = map(Base.Fix2(in, diffvars), sts)
kwargs = filter_kwargs(kwargs)
kwargs1 = (;)
tstops = SymbolicTstops(sys; eval_expression, eval_module)
if tstops !== nothing
kwargs1 = merge(kwargs1, (; tstops))
end
DAEProblem{iip}(f, du0, u0, tspan, p; differential_vars = differential_vars,
kwargs..., kwargs1...)
end
function generate_history(sys::AbstractODESystem, u0; expression = Val{false}, kwargs...)
p = reorder_parameters(sys, parameters(sys))
build_function(u0, p..., get_iv(sys); expression, kwargs...)
end
function DiffEqBase.DDEProblem(sys::AbstractODESystem, args...; kwargs...)
DDEProblem{true}(sys, args...; kwargs...)
end
function DiffEqBase.DDEProblem{iip}(sys::AbstractODESystem, u0map = [],
tspan = get_tspan(sys),
parammap = DiffEqBase.NullParameters();
callback = nothing,
check_length = true,
eval_expression = false,
eval_module = @__MODULE__,
u0_constructor = identity,
kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating a `DDEProblem`")
end
f, u0, p = process_SciMLProblem(DDEFunction{iip}, sys, u0map, parammap;
t = tspan !== nothing ? tspan[1] : tspan,
symbolic_u0 = true,
check_length, eval_expression, eval_module, kwargs...)
h_gen = generate_history(sys, u0; expression = Val{true})
h_oop, h_iip = eval_or_rgf.(h_gen; eval_expression, eval_module)
h(p, t) = h_oop(p, t)
h(p::MTKParameters, t) = h_oop(p..., t)
u0 = float.(h(p, tspan[1]))
if u0 !== nothing
u0 = u0_constructor(u0)
end
cbs = process_events(sys; callback, eval_expression, eval_module, kwargs...)
kwargs = filter_kwargs(kwargs)
kwargs1 = (;)
if cbs !== nothing
kwargs1 = merge(kwargs1, (callback = cbs,))
end
DDEProblem{iip}(f, u0, h, tspan, p; kwargs1..., kwargs...)
end
function DiffEqBase.SDDEProblem(sys::AbstractODESystem, args...; kwargs...)
SDDEProblem{true}(sys, args...; kwargs...)
end
function DiffEqBase.SDDEProblem{iip}(sys::AbstractODESystem, u0map = [],
tspan = get_tspan(sys),
parammap = DiffEqBase.NullParameters();
callback = nothing,
check_length = true,
sparsenoise = nothing,
eval_expression = false,
eval_module = @__MODULE__,
u0_constructor = identity,
kwargs...) where {iip}
if !iscomplete(sys)
error("A completed system is required. Call `complete` or `structural_simplify` on the system before creating a `SDDEProblem`")
end
f, u0, p = process_SciMLProblem(SDDEFunction{iip}, sys, u0map, parammap;
t = tspan !== nothing ? tspan[1] : tspan,
symbolic_u0 = true, eval_expression, eval_module,
check_length, kwargs...)
h_gen = generate_history(sys, u0; expression = Val{true})
h_oop, h_iip = eval_or_rgf.(h_gen; eval_expression, eval_module)
h(out, p, t) = h_iip(out, p, t)
h(p, t) = h_oop(p, t)
h(p::MTKParameters, t) = h_oop(p..., t)
h(out, p::MTKParameters, t) = h_iip(out, p..., t)
u0 = h(p, tspan[1])
if u0 !== nothing
u0 = u0_constructor(u0)
end
cbs = process_events(sys; callback, eval_expression, eval_module, kwargs...)
kwargs = filter_kwargs(kwargs)
kwargs1 = (;)
if cbs !== nothing
kwargs1 = merge(kwargs1, (callback = cbs,))
end
noiseeqs = get_noiseeqs(sys)
sparsenoise === nothing && (sparsenoise = get(kwargs, :sparse, false))
if noiseeqs isa AbstractVector
noise_rate_prototype = nothing
elseif sparsenoise
I, J, V = findnz(SparseArrays.sparse(noiseeqs))
noise_rate_prototype = SparseArrays.sparse(I, J, zero(eltype(u0)))
else
noise_rate_prototype = zeros(eltype(u0), size(noiseeqs))
end
SDDEProblem{iip}(f, f.g, u0, h, tspan, p;
noise_rate_prototype =
noise_rate_prototype, kwargs1..., kwargs...)
end
"""
```julia
ODEProblemExpr{iip}(sys::AbstractODESystem, u0map, tspan,
parammap = DiffEqBase.NullParameters();