-
Notifications
You must be signed in to change notification settings - Fork 16
/
Copy pathQuantumSystems.m
1468 lines (1041 loc) · 38.3 KB
/
QuantumSystems.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* ::Title:: *)
(*QuantumUtils for Mathematica*)
(*Quantum Systems Package*)
(* ::Subsection::Closed:: *)
(*Copyright and License Information*)
(* ::Text:: *)
(*This package is part of QuantumUtils for Mathematica.*)
(**)
(*Copyright (c) 2015 and later, Christopher J. Wood, Christopher E. Granade, Ian N. Hincks*)
(**)
(*Redistribution and use in source and binary forms, with or withoutmodification, are permitted provided that the following conditions are met:*)
(*1. Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.*)
(*2. Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.*)
(*3. Neither the name of quantum-utils-mathematica nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.*)
(**)
(*THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THEIMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE AREDISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLEFOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIALDAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS ORSERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVERCAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USEOF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.*)
(* ::Subsection::Closed:: *)
(*Preamble*)
BeginPackage["QuantumSystems`",{"QUDoc`","Predicates`","Tensor`"}];
Needs["QUDevTools`"]
$QuantumSystemsUsages = LoadUsages[FileNameJoin[{$QUDocumentationPath, "api-doc", "QuantumSystems.nb"}]];
(* ::Section::Closed:: *)
(*Usage Declaration*)
(* ::Subsection::Closed:: *)
(*States, Operators and Gates*)
Unprotect[Spin,Cavity,QState,CGate,KetForm,VecForm,Ket,Bra,KetBra];
AssignUsage[Spin,$QuantumSystemsUsages];
AssignUsage[Cavity,$QuantumSystemsUsages];
AssignUsage[QState,$QuantumSystemsUsages];
AssignUsage[KetForm,$QuantumSystemsUsages];
AssignUsage[VecForm,$QuantumSystemsUsages];
AssignUsage[CGate,$QuantumSystemsUsages];
(* ::Subsection::Closed:: *)
(*Symbolic Evaluation*)
Unprotect[Op,QPower,QExpand,QPowerExpand,QSimplifyRules,QSimplify,ClearQSimplifyCache];
AssignUsage[QExpand,$QuantumSystemsUsages];
AssignUsage[QPower,$QuantumSystemsUsages];
AssignUsage[QPowerExpand,$QuantumSystemsUsages];
AssignUsage[QSimplifyRules,$QuantumSystemsUsages];
AssignUsage[QSimplify,$QuantumSystemsUsages];
AssignUsage[ClearQSimplifyCache,$QuantumSystemsUsages];
(* ::Subsection::Closed:: *)
(*State Measures*)
Unprotect[EntropyH,EntropyS,RelativeEntropyS,MutualInformationS];
Unprotect[Purity,PNorm,Fidelity,EntangledQ,Concurrence,EntanglementF];
AssignUsage[EntropyH,$QuantumSystemsUsages];
AssignUsage[EntropyS,$QuantumSystemsUsages];
AssignUsage[RelativeEntropyS,$QuantumSystemsUsages];
AssignUsage[MutualInformationS,$QuantumSystemsUsages];
AssignUsage[Purity,$QuantumSystemsUsages];
AssignUsage[PNorm,$QuantumSystemsUsages];
AssignUsage[Fidelity,$QuantumSystemsUsages];
AssignUsage[EntangledQ,$QuantumSystemsUsages];
AssignUsage[Concurrence,$QuantumSystemsUsages];
AssignUsage[EntanglementF,$QuantumSystemsUsages];
(* ::Subsection::Closed:: *)
(*Random Matrices*)
Unprotect[RandomUnitary,RandomDensity,RandomHermitian];
AssignUsage[RandomUnitary,$QuantumSystemsUsages];
AssignUsage[RandomDensity,$QuantumSystemsUsages];
AssignUsage[RandomHermitian,$QuantumSystemsUsages];
(* ::Subsection::Closed:: *)
(*Error Messages*)
(* ::Subsubsection::Closed:: *)
(*States and Operators*)
Spin::spin = "Total spin value must be an non-negative integer or half-integer; `1` received.";
Cavity::dim = "Cavity dimension must be a positive integer.";
VecForm::fail = "Unable to parse input.";
KetForm::input = "Input must be a rank 1 or 2 array.";
(* ::Subsubsection::Closed:: *)
(*Symbolic Evaluation*)
QSimplifyRules::alg = "Commutator algebra matrix must be upper triangular, lower triangular, or skew-symmetric.";
QSimplifyRules::ragls = "Invalid algebra input list.";
QSimplifyRules::comlen = "Commutator algebra matrix does not match number of operators.";
QSimplifyRules::dotlen = "Dot matrix does not match number of operators.";
(* ::Subsubsection::Closed:: *)
(*Quantum Gates*)
CGate::dims = "Input dimensions must be an integer or list of integers";
CGate::targctrl = "Targets and Control subsystem lists must not intersect.";
CGate::gates = "Gate must be matrix or a list of matrices of same length as list of targets.";
CGate::ctrlval = "Control values must be integer or list of integers same length as controls list.";
(* ::Subsubsection::Closed:: *)
(*Measures*)
Fidelity::input = "Input must be satisfy either SquareMatrixQ or GeneralVectorQ.";
EntropyS::sqmat = "Input must be a square matrix.";
MutualInformationS::sqmat = "Input must be a square matrix.";
MutualInformationS::dims = "Computed subsystem dimensions not integers manually specify dimensions.";
RelativeEntropyS::sqmat = "Input must be a square matrix.";
Purity::sqmat = "Input must be a square matrix.";
EntangledQ::input = "Input must be satisfy either SquareMatrixQ or GeneralVectorQ.";
Concurrence::input = "Input must be satisfy either SquareMatrixQ or GeneralVectorQ.";
Concurrence::dim = "Concurrence currently only works for 2-qubit states.";
EntanglementF::input = "Input must be satisfy either SquareMatrixQ or GeneralVectorQ.";
EntanglementF::dim = "Concurrence currently only works for 2-qubit states.";
(* ::Section::Closed:: *)
(*Implementation*)
Begin["`Private`"];
(* ::Subsection::Closed:: *)
(*States and Operators*)
(* ::Subsubsection::Closed:: *)
(*Spin Operators*)
SpinQ[S_]:=IntegerQ[2*S]&&NonNegative[2*S]
Clear[SpinZ,SpinP]
SpinZ[S_]:=SpinZ[S]=DiagonalMatrix[SparseArray[Range[S,-S,-1]]];
SpinP[S_]:=SpinP[S]=SparseArray[{#,#+1}->Sqrt[(1+2 S-#) #]&/@Range[2S],{2S+1,2S+1}];
SpinM[S_]:=Transpose[SpinP[S]];
SpinX[S_]:=(SpinP[S]+SpinM[S])/2
SpinY[S_]:=(SpinM[S]-SpinP[S])*I/2
SpinI[S_]:=IdentityMatrix[2S+1,SparseArray];
Clear[SpinTPRules]
SpinTPRules[S_]:= SpinTPRules[S] =
MapThread[Rule,
{{"I","X","Y","Z","P","M"},
If[S==="Symbolic",
{Spin["I"],Spin["X"],Spin["Y"],Spin["Z"],Spin["P"],Spin["M"]},
{SpinI[S],SpinX[S],SpinY[S],SpinZ[S],SpinP[S],SpinM[S]}
]}
]
SetAttributes[Spin,HoldAllComplete]
Spin[expr_][S_,SparseArray]:=With[
{spin=Rationalize[S]},
If[SpinQ[spin],
TP[expr,Replace->SpinTPRules[S]],
Message[Spin::spin,spin]
]]
Spin[expr_][S_]:=Normal[Spin[expr][S,SparseArray]]
Spin[expr_][S_,Identity]:=Spin[expr][S]
Spin[expr_]["Symbolic"]:=TP[expr,Replace->SpinTPRules["Symbolic"]]
(* ::Text:: *)
(*Short hand for single spin operators*)
Spin[0]:=Spin["I"]
Spin[1]:=Spin["X"]
Spin[2]:=Spin["Y"]
Spin[3]:=Spin["Z"]
(* ::Text:: *)
(*Display Formatting*)
SpinFormatting[Spin[op_]]:=
With[{str=ToString@Unevaluated[op]},
Which[
str=="P", Subscript[Style["S",Italic],"+"],
str=="M", Subscript[Style["S",Italic],"-"],
str=="X", Subscript[Style["S",Italic],"x"],
str=="Y", Subscript[Style["S",Italic],"y"],
str=="Z", Subscript[Style["S",Italic],"z"],
str=="I", Subscript["\[DoubleStruckOne]","s"],
True,"Spin"[str]
]]
Format[Spin[op_],TraditionalForm]:=SpinFormatting[Spin[op]]
(* ::Subsubsection::Closed:: *)
(*Cavity Operators*)
Clear[CavityA,CavityN]
CavityI[n_Integer]:= IdentityMatrix[n,SparseArray]
CavityA[n_Integer]:= CavityA[n] = DiagonalMatrix[SparseArray@Sqrt[Range[n-1]],1]
CavityC[n_Integer]:= Transpose[CavityA[n]]
CavityN[n_Integer]:= CavityN[n] = DiagonalMatrix[SparseArray@Range[0,n-1]]
CavityTPRules[n_]:= CavityTPRules[n] =
MapThread[Rule,
{{"I","a","c","n","N"},
If[n==="Symbolic",
{Cavity["I"],Cavity["a"],Cavity["c"],Cavity["n"],Cavity["n"]},
{CavityI[n],CavityA[n],CavityC[n],CavityN[n],CavityN[n]}
]}
]
SetAttributes[Cavity,HoldAllComplete]
Cavity[expr_][n_Integer,SparseArray]:=
If[Positive[n],
TP[expr,Replace->CavityTPRules[n]],
Message[Cavity::int]
]
Cavity[expr_][n_Integer]:=Normal[Cavity[expr][n,SparseArray]]
Cavity[expr_][n_Integer,Identity]:=Cavity[expr][n]
Cavity[expr_]["Symbolic"]:=TP[expr,Replace->CavityTPRules["Symbolic"]]
(* ::Text:: *)
(*Display Formatting*)
CavityFormatting[Cavity[op_]]:=
With[{str=ToString@Unevaluated[op]},
Which[
str=="a", Style["a",Italic],
str=="c", Superscript[Style["a",Italic],"\[Dagger]"],
str=="n"||str=="N", Style["N",Italic],
str=="I", Subscript["\[DoubleStruckOne]","c"],
True, "Cavity"[str]
]]
Format[Cavity[op_],TraditionalForm]:=CavityFormatting[Cavity[op]]
(* ::Subsubsection::Closed:: *)
(*Quantum States*)
SetAttributes[QState,HoldAllComplete];
Options[QState]:={VectorQ->False, ColumnVectorQ->False};
QState[expr__,opts:OptionsPattern[]]:=
Which[
AllMatchQ[{_,_,_},{expr}],
CircleTimes@@Map[QStateBloch,{expr}],
TrueQ[OptionValue[VectorQ]],
TP[Unevaluated[expr],Replace->$QStateVecRules],
TrueQ[OptionValue[ColumnVectorQ]],
Partition[TP[Unevaluated[expr],Replace->$QStateVecRules],1],
True,TP[Unevaluated[expr],Replace->$QStateMatRules]
]
QStateBloch[{x_,y_,z_}]:={{1+z,x-I*y},{x+I*y,1-z}}/2;
(* ::Text:: *)
(*Rules for state vectors*)
$QStateVecZp={1,0};
$QStateVecZm={0,1};
$QStateVecXp={1,1}/Sqrt[2];
$QStateVecXm={1,-1}/Sqrt[2];
$QStateVecYp={1,I}/Sqrt[2];
$QStateVecYm={1,-I}/Sqrt[2];
$QStateVecBell1={1,0,0,1}/Sqrt[2];
$QStateVecBell2={0,1,1,0}/Sqrt[2];
$QStateVecBell3={0,1,-1,0}/Sqrt[2];
$QStateVecBell4={1,0,0,-1}/Sqrt[2];
$QStateVecRules={
"Zp"->$QStateVecZp, "H"->$QStateVecZp,
"Zm"->$QStateVecZm, "V"->$QStateVecZm,
"Xp"->$QStateVecXp, "D"->$QStateVecXp,
"Xm"->$QStateVecXm, "A"->$QStateVecXm,
"Yp"->$QStateVecYp, "R"->$QStateVecYp,
"Ym"->$QStateVecYm, "L"->$QStateVecYm,
"Bell1"->$QStateVecBell1, "B1"->$QStateVecBell1,
"Bell2"->$QStateVecBell2, "B2"->$QStateVecBell2,
"Bell3"->$QStateVecBell3, "B3"->$QStateVecBell3,
"Bell4"->$QStateVecBell4, "B4"->$QStateVecBell4};
(* ::Text:: *)
(*Rules for density matrices*)
$QStateMatZp=Projector[$QStateVecZp];
$QStateMatZm=Projector[$QStateVecZm];
$QStateMatXp=Projector[$QStateVecXp];
$QStateMatXm=Projector[$QStateVecXm];
$QStateMatYp=Projector[$QStateVecYp];
$QStateMatYm=Projector[$QStateVecYm];
$QStateMatBell1=Projector[$QStateVecBell1];
$QStateMatBell2=Projector[$QStateVecBell2];
$QStateMatBell3=Projector[$QStateVecBell3];
$QStateMatBell4=Projector[$QStateVecBell4];
$QStateMixed={{1/2,0},{0,1/2}};
$QStateMatRules={
"I"->$QStateMixed,
"Zp"->$QStateMatZp, "H"->$QStateMatZp,
"Zm"->$QStateMatZm, "V"->$QStateMatZm,
"Xp"->$QStateMatXp, "D"->$QStateMatXp,
"Xm"->$QStateMatXm, "A"->$QStateMatXm,
"Yp"->$QStateMatYp, "R"->$QStateMatYp,
"Ym"->$QStateMatYm, "L"->$QStateMatYm,
"Bell1"->$QStateMatBell1, "B1"->$QStateMatBell1,
"Bell2"->$QStateMatBell2, "B2"->$QStateMatBell2,
"Bell3"->$QStateMatBell3, "B3"->$QStateMatBell3,
"Bell4"->$QStateMatBell4, "B4"->$QStateMatBell4};
(* ::Subsubsection::Closed:: *)
(*Bra-Ket Notation*)
(* ::Text:: *)
(*Converting arrays to Bra-Ket Notation.*)
KetForm[op_,subdims___]:=
With[{dims=Dimensions[op]},
Which[
GeneralVectorQ[op],
KetFormVector[Ket,op,subdims],
RowVectorQ[op],
KetFormVector[Bra,op,subdims],
MatrixQ[op],
KetFormMatrix[op,subdims],
True,
Message[KetForm::input]
]]
(* ::Text:: *)
(*Display Formatting*)
Format[KetBra[{a__},{b__}]]:=
DisplayForm[
RowBox[{"\[LeftBracketingBar]",
Sequence@@Map[AdjustmentBox[#,BoxMargins->{{0,0},{0.5,0.5}}]&,{a}],
AdjustmentBox["\[RightAngleBracket]",BoxMargins->{{0,-0.5},{0,0}}],
"\[LeftAngleBracket]",
Sequence@@Map[AdjustmentBox[#,BoxMargins->{{0,0},{0.5,0.5}}]&,{b}],
"\[RightBracketingBar]"}]]
(* ::Text:: *)
(*Conversion Utility functions*)
KetBasis[ds_List]:=Tuples@Map[Table[Subscript[i, #],{i,0,#-1}]&,ds]
KetAutoDim[d_]:=
Which[
IntegerQ[Log[2,d]],
ConstantArray[2,Log[2,d]],
IntegerQ[Log[3,d]],
ConstantArray[3,Log[3,d]],
True,d]
(* ::Text:: *)
(*Converting vectors to KetForm*)
KetFormVector[ket_,vec_,ds_List]:=Flatten[vec].(ket@@@KetBasis[ds]);
KetFormVector[ket_,vec_,d_Integer]:=
With[{ds=ConstantArray[d,Log[d,Length[Flatten[vec]]]]},
KetFormVector[ket,vec,ds]
]
KetFormVector[ket_,vec_]:=
With[{d=KetAutoDim[Length[Flatten[vec]]]},
KetFormVector[ket,vec,d]
]
(* ::Text:: *)
(*Converting matrices to KetForm*)
KetFormMatrix[mat_,dsL_List,dsR_List]:=
Flatten[mat].(KetBra@@@Tuples[{KetBasis[dsL],KetBasis[dsR]}]);
KetFormMatrix[mat_,ds_List]:=KetFormMatrix[mat,ds,ds];
KetFormMatrix[mat_,d_Integer]:=
With[{n=Log[d,Length[mat]]},
If[IntegerQ[Log[d,Length[mat]]],
KetFormMatrix[mat,ConstantArray[d,n]],
KetFormMatrix[mat,{First[Dimensions[mat]]},{Last[Dimensions[mat]]}]]
];
KetFormMatrix[mat_]:=
With[{dims=KetAutoDim/@Dimensions[mat]},
KetFormMatrix[mat,Sequence@@dims]
]
(* ::Subsubsection::Closed:: *)
(*Vec Form*)
(* ::Text:: *)
(*Converting Spin, Cavity and Bra-Ket notation to arrays.*)
KetDimensions[Subscript[num_,dim_]]:={dim,1+num};
KetDimensions[num_]:={2,1+num};
Options[VecForm]:={Spin->1/2,Cavity->2,SparseArray->False};
VecForm[obj_,opts:OptionsPattern[VecForm]]:=
With[{f=If[OptionValue[SparseArray],SparseArray,Identity]},
Which[
(* Linear Algebra *)
NumericQ[obj],obj,
ListQ[obj],f@obj,
StringQ[obj],obj,
MatchQ[obj,Plus[_,__]],
VecForm[First[obj],opts]+VecForm[Rest[obj],opts],
MatchQ[obj,Times[_?CoefficientQ,__]],
obj/.{Times[a_?CoefficientQ,b__]:>Times[a,VecForm[Times[b],opts]]},
MatchQ[obj,CircleTimes[_,__]],
CircleTimes@@Map[VecForm[#,opts]&,List@@obj],
MatchQ[obj,Dot[_,__]],
Dot@@Map[VecForm[#,opts]&,List@@obj],
MatchQ[obj,QPower[_,_]],
MatrixPower[VecForm[First@obj,opts],VecForm[Last@obj,opts]],
(* Bra-Ket *)
MatchQ[obj,Ket[{__}]],
Partition[CircleTimes@@Apply[Composition[f,UnitVector],Map[KetDimensions,First@obj],{1}],1],
MatchQ[obj,Ket[__]],
Partition[CircleTimes@@Apply[Composition[f,UnitVector],Map[KetDimensions,List@@obj],{1}],1],
MatchQ[obj,Bra[{__}]],
ConjugateTranspose[VecForm[Ket@@First[obj],opts]],
MatchQ[obj,Bra[__]],
ConjugateTranspose[VecForm[Ket@@obj,opts]],
MatchQ[obj,KetBra[{__},{__}]],
CircleTimes[VecForm[Ket@@First[obj]],VecForm[Bra@@Last[obj],opts]],
(* Spin-Cavity *)
MatchQ[obj,Spin[__]],
obj[OptionValue[Spin],f],
MatchQ[obj,Cavity[__]],
obj[OptionValue[Cavity],f],
(* Symbolic *)
CoefficientQ[obj],obj,
(* Failure *)
True,
Message[VecForm::fail]
]]
VecForm[a__,opts:OptionsPattern[VecForm]]:=Map[VecForm[#,opts]&,{a}]
(* ::Subsection::Closed:: *)
(*Symbolic Evaluation*)
(* ::Subsubsection::Closed:: *)
(*Symbolic Operators*)
(* ::Text:: *)
(*Use container Op for symbolic operators*)
(* ::Text:: *)
(*QPower for powers of symbolic operators*)
QPower[a_]:=a
QPower[arg_,1]:=arg
QPower[arg_?CoefficientQ,n_]:=Power[arg,n]
QPower[arg_?MatrixQ,n_]:=MatrixPower[arg,n]
QPower[QPower[arg_,m_],n_]:=QPower[arg,m+n]
QPower[Times[x_?CoefficientQ,xs__],n_]:=QPower[x,n]*QPower[Times[xs],n]
QPower[Times[xs__,x_?CoefficientQ],n_]:=QPower[x,n]*QPower[Times[xs],n]
QPower[CircleTimes[a_,b__],n_]:=CircleTimes[QPower[a,n],QPower[CircleTimes[b],n]]
(*QPower[Dot[a_,b__],n_Integer]:=Dot[Sequence@@Flatten[ConstantArray[{a,b},n]]]*)
(* ::Text:: *)
(*Hide QPower from displayed equations*)
Format[QPower[arg_,n_]]:=arg^n;
(* ::Text:: *)
(*Parsing symbolic Spin-Cavity expressions*)
QExpand[expr_]:=ReplaceRepeated[expr,{Spin[arg_]:> Spin[arg]["Symbolic"],Cavity[arg_]:> Cavity[arg]["Symbolic"]}]
(* ::Subsubsection::Closed:: *)
(*QSimplify*)
Options[QSimplify]:={
Spin->True,
Cavity->True,
"SpinAlgebra"->Automatic,
"CavityAlgebra"->"n",
"SpinHalf"->False,
"OrderSpin"->False,
"OrderCavity"->True,
TimeConstraint->1,
QPowerExpand->True};
QSimplify[expr_,rules_?ListQ,opts:OptionsPattern[QSimplify]]:= QSimplifyCached[expr,rules,opts]
QSimplify[expr_,opts:OptionsPattern[QSimplify]]:= QSimplify[expr,{},opts]
QSimplify[Com[a_,b_,n_?Positive],rules_?ListQ,opts:OptionsPattern[]]:=QSimplify[Com[a,QSimplify[Com[a,b],opts],n-1],rules,opts]
QSimplify[ACom[a_,b_,n_?Positive],rules_?ListQ,opts:OptionsPattern[]]:=QSimplify[ACom[a,QSimplify[ACom[a,b],opts],n-1],rules,opts]
QPowerExpand[expr_]:=expr//.{QPower[Plus[a_,b__],n_Integer]:>Dot@@ConstantArray[Plus[a,b],n]}
QPowerExpand[expr_,nMax_Integer]:=expr//.{QPower[Plus[a_,b__],n_?(IntegerQ[#]&&#<=nMax&)]:>Dot@@ConstantArray[Plus[a,b],n]}
(* ::Text:: *)
(*Memoized function for QSimplify*)
Clear[QSimplifyCached];
QSimplifyCachedOld[expr_,rules_,opts:OptionsPattern[QSimplify]]:=
QSimplifyCached[expr,rules,opts]=
With[{replaceRules=Join[QSimplifyDefaultRules[opts],rules]},
Simplify[
ReplaceRepeated[
Simplify[QExpand[expr],TimeConstraint->OptionValue[TimeConstraint]],
replaceRules
],
TimeConstraint->OptionValue[TimeConstraint]]]
QSimplifyCached[expr_,rules_,opts:OptionsPattern[QSimplify]]:=
QSimplifyCached[expr,rules,opts]=
With[{
replaceRules=Join[QSimplifyDefaultRules[opts],rules],
qexpand=OptionValue[QPowerExpand]},
With[{
OuterSimplify=Which[
MemberQ[{True,All,\[Infinity]},qexpand],
Simplify[QPowerExpand[#],TimeConstraint->OptionValue[TimeConstraint]]&,
IntegerQ[qexpand],
Simplify[QPowerExpand[#,qexpand],TimeConstraint->OptionValue[TimeConstraint]]&,
True,
Simplify[#,TimeConstraint->OptionValue[TimeConstraint]]&
]},
FixedPoint[
OuterSimplify@ReplaceRepeated[
Simplify[#,TimeConstraint->OptionValue[TimeConstraint]],
Join[QSimplifyDefaultRules[opts],rules]]&,
Simplify[QExpand[expr],TimeConstraint->OptionValue[TimeConstraint]]
]
]]
(* ::Text:: *)
(*Function to clear cached QSimplify values*)
ClearQSimplifyCache[]:=(
DownValues[QSimplifyCached]=Part[DownValues[QSimplifyCached],{-1}];
DownValues[QSimplifyDefaultRules]=Part[DownValues[QSimplifyDefaultRules],{-1}];)
(* ::Text:: *)
(*Default replacement rules for QSimplify*)
Clear[QSimplifyDefaultRules]
QSimplifyDefaultRules[opts:OptionsPattern[QSimplify]]:=
QSimplifyDefaultRules[opts]=
Join[
$QSimplifyLinearAlgebra,
QSimplifySpinRules[opts],
QSimplifyCavityRules[opts],
QSimplifyPower[Op]
]
QSimplifySpinRules[opts:OptionsPattern[QSimplify]]:=
If[OptionValue[Spin],
Join[
If[OptionValue["SpinHalf"],$QSimplifySpinHalf,{}],
Which[
OptionValue["SpinAlgebra"]==="PM", $QSimplifySpinPM,
OptionValue["SpinAlgebra"]==="XY", $QSimplifySpinXY,
True,{}],
$QSimplifySpin,
If[OptionValue["OrderSpin"],$QSimplifySpinOrdering,{}]
],{}]
QSimplifyCavityRules[opts:OptionsPattern[QSimplify]]:=
If[OptionValue[Cavity],
Join[
If[OptionValue["OrderCavity"],$QSimplifyCavityOrdering,{}],
Which[
OptionValue["CavityAlgebra"]==="n", $QSimplifyCavityN,
OptionValue["CavityAlgebra"]==="ac", $QSimplifyCavityAC,
True,{}],
$QSimplifyCavity,{}
],{}]
(* ::Subsubsection::Closed:: *)
(*QSimplifyRules*)
(* ::Text:: *)
(*Function for constructing QSimplify Rules*)
Options[QSimplifyRules]:={
Protect->True,
Power->True,
Identity->None,
Com->None,
Dot->None,
Transpose->None,
Conjugate->None,
ConjugateTranspose->None,
"NormalOrder"->False
};
QSimplifyRules[opLabel_,ops_?ListQ,opts:OptionsPattern[QSimplifyRules]]:=
With[{
attr=OptionValue[Protect],
id=OptionValue[Identity],
order=OptionValue["NormalOrder"],
comAlg=OptionValue[Com],
ctOps=OptionValue[ConjugateTranspose],
tOps=OptionValue[Transpose],
cOps=OptionValue[Conjugate],
dotAlg=OptionValue[Dot]},
If[MemberQ[{Automatic,True},attr],Protect[opLabel]];
Join[
If[MemberQ[{Automatic,True},OptionValue[Power]],
QSimplifyPower[opLabel],
{}],
Which[
MemberQ[{Automatic,True},id],QSimplifyIdentity[opLabel["I"]],
MemberQ[{False,None},id],{},
True, QSimplifyIdentity[id]],
If[MemberQ[{False,None},comAlg],
{},
QSimplifyCom[ops,comAlg]],
If[MemberQ[{False,None},ctOps],
{},
QSimplifyFunction[ConjugateTranspose,ops,ctOps]],
If[MemberQ[{False,None},tOps],
{},
QSimplifyFunction[Transpose,ops,tOps]],
If[MemberQ[{False,None},cOps],
{},
QSimplifyFunction[Conjugate,ops,cOps]],
If[MemberQ[{False,None},dotAlg],
{},
QSimplifyDot[ops,dotAlg]],
Which[
MemberQ[{False,None},order],{},
MemberQ[{Automatic,True},order],QSimplifyNormalOrder[opLabel,ops],
True,QSimplifyNormalOrder[opLabel,order]]
]]
(* ::Subsubsection::Closed:: *)
(*QSimplifyRules Constructors*)
(* ::Text:: *)
(*General function constructor*)
QSimplifyFunction[fn_,ops_,opsFn_]:=
Select[
MapThread[fn[#1]:>#2&,{ops,opsFn}],
Not[MatchQ[#,_:>None]]&
]
(* ::Text:: *)
(*Commutator constructors*)
QSimplifyCom[ops_List,algebra_]:=
With[{mat=QSimplifyComMatrix[algebra]},
If[Length[mat]===Length[ops],
Select[
Flatten[
MapThread[
RuleDelayed,
{Outer[Com[#1,#2]&,ops,ops],
QSimplifyComMatrix[algebra]},2]
],
Not[MatchQ[#,_:>None]]||Not[MatchQ[#,0:>_]]&],
Message[QSimplifyRules::comlen]
]]
QSimplifyComMatrix[algebra_]:=
Which[
And[ListQ[algebra],{1}===Dimensions[algebra]],
QSimplifyComMatrixRagged[{algebra}],
And[MatrixQ[algebra],{1,1}===Dimensions[algebra]],
QSimplifyComMatrixRagged[algebra],
MatrixQ[algebra],
QSimplifyComMatrixSkew[algebra],
ListQ[algebra],
QSimplifyComMatrixRagged[algebra],
True,
QSimplifyComMatrixRagged[{{algebra}}]
]
(* ::Text:: *)
(*Constructing algebra matrix for skew, upper or lower triangular matrices*)
QSimplifyComMatrixSkew[mat_?MatrixQ]:=
With[{utri=UpperTriangularize[mat,1],ltri=LowerTriangularize[mat,-1]},
Which[
AllMatchQ[0,Flatten[utri]], ltri-Transpose[ltri],
AllMatchQ[0,Flatten[ltri]], utri-Transpose[utri],
AllMatchQ[0,Flatten[utri+Transpose[ltri]]], utri+ltri,
True, Message[QSimplifyRules::alg]
]]
(* ::Text:: *)
(*Constructing algebra matrix for ragged lists*)
QSimplifyComMatrixRagged[raggedls_]:=
With[{d=Length[First@raggedls]},
If[Flatten[Dimensions/@raggedls]===Range[d,1,-1],
QSimplifyComMatrixSkew[PadRight[PadLeft[raggedls,{d,d+1}],{d+1,d+1}]],
Message[QSimplifyRules::ragls]]
]
(* ::Text:: *)
(*Dot constructors*)
QSimplifyDot[ops_,algebra_]:=
If[Dimensions[algebra]==={#,#}&@Length[ops],
Select[
Flatten[
MapThread[
RuleDelayed,
{Outer[Dot[#1,#2]&,ops,ops],algebra}
,2]
],
Not[MatchQ[#,_:>None]]&],
Message[QSimplifyRules::dotlen]
]
(* ::Text:: *)
(*Identity operator constructor*)
QSimplifyIdentity[id_]:={
Dot[id,op_]:> op,
Dot[id,QPower[op_,m_]]:> QPower[op,m],
Dot[op_,id]:> op,
Dot[QPower[op_,m_],id]:> QPower[op,m],
QPower[id,n_]:> id,
Com[id,s_]:> 0,
Com[s_,id]:> 0,
ConjugateTranspose[id]:> id,
Transpose[id]:> id,
Conjugate[id]:> id
};
(* ::Text:: *)
(*Operator power constructor*)
QSimplifyPower[container_]:={
Power[op_container,n_]:> QPower[op,n],
MatrixPower[op_container,n_]:> QPower[op,n]
};
(* ::Text:: *)
(*Normal Ordering constructors*)
NormalOrderRight[opls_List,op_]:=Join[
Map[{
op.#:>#.op+Com[op,#],
op.QPower[#,m_]:> QPower[#,m].op+Com[op,QPower[#,m]],
QPower[op,n_].#:> #.QPower[op,n]+Com[QPower[op,n],#],
QPower[op,n_].QPower[#,m_]:> QPower[#,m].QPower[op,n]+Com[QPower[op,n],QPower[#,m]]
}&,opls]];
NormalOrderRight[container_,op_]:={
op.container[s_]:>container[s].op+Com[op,container[s]],
op.QPower[container[s_],m_]:> QPower[container[s],m].op+Com[op,QPower[container[s],m]],
QPower[op,n_].container[s_]:> container[s].QPower[op,n]+Com[QPower[op,n],container[s]],
QPower[op,n_].QPower[container[s_],m_]:> QPower[container[s],m].QPower[op,n]+Com[QPower[op,n],QPower[container[s],m]]
};
NormalOrderLeft[opls_List,op_]:=Join[
Map[{
#.op:> op.#+Com[#,op],
#.QPower[op,n_]:> QPower[op,n].#+Com[#,QPower[op,n]],
QPower[#,m_].op:> op.QPower[#,m]+Com[QPower[#,m],op],
QPower[#,m_].QPower[op,n_]:> QPower[op,n].QPower[#,m]+Com[QPower[#,m],QPower[op,n]]
}&,opls]];
NormalOrderLeft[container_,op_]:={
container[s_].op:> op.container[s]+Com[container[s],op],
container[s_].QPower[op,n_]:> QPower[op,n].container[s]+Com[container[s],QPower[op,n]],
QPower[container[s_],m_].op:> op.QPower[container[s],m]+Com[QPower[container[s],m],op],
QPower[container[s_],m_].QPower[op,n_]:> QPower[op,n].QPower[container[s],m]+Com[QPower[container[s],m],QPower[op,n]]
};
NormalOrderList[ops_]:=
If[Length[ops]<2,{},
Flatten@Join[
NormalOrderLeft[Rest[ops],First[ops]],
NormalOrderRight[ops[[2;;-2]],Last[ops]],
NormalOrderList[ops[[2;;-2]]]
]
];
QSimplifyNormalOrder[container_,ops_List]:=
Join[
NormalOrderLeft[container,First[ops]],
NormalOrderRight[container,Last[ops]],
NormalOrderList[ops[[2;;-2]]]
];
(* ::Subsubsection::Closed:: *)
(*Linear Algebra Rules*)
$QSimplifyLinearAlgebra={
(* Times *)
Times[Plus[a_,b__],c_]:>Expand[Times[Plus[a,b],c]],
(* Dot *)
Dot[a_,QPower[a_,n_]]:> QPower[a,n+1],
Dot[a_,Plus[b_,c__]]:> Dot[a,b]+Dot[a,Plus[c]],
Dot[a_,a_]:> QPower[a,2],
Dot[QPower[a_,n_],a_]:> QPower[a,n+1],
Dot[QPower[a_,m_],QPower[a_,n_]]:> QPower[a,n+m],
Dot[Plus[a_,b__],c_]:> Dot[a,c]+Dot[Plus[b],c],
Dot[a_,n_?CoefficientQ]:> n*Dot[a],
Dot[n_?CoefficientQ,b_]:> n*Dot[b],
Dot[a_,Times[b_?CoefficientQ,c__]]:> b*Dot[a,Times[c]],
Dot[a_,Times[c__,b_?CoefficientQ]]:> b*Dot[a,Times[c]],
Dot[Times[a_?CoefficientQ,b__],c_]:> a*Dot[Times[b],c],
Dot[Times[b__,a_?CoefficientQ],c_]:> a*Dot[Times[b],c],
Dot[CircleTimes[a1_,b1__],CircleTimes[a2_,b2__]]:> CircleTimes@@MapThread[Dot,{{a1,b1},{a2,b2}}],
(* CircleTimes *)
KroneckerProduct[a_,b__]:> CircleTimes[a,b],
CircleTimes[Plus[a_,b__],c_]:> Plus@@Map[CircleTimes[#,c]&,{a,b}],
CircleTimes[c_,Plus[a_,b__]]:> Plus@@Map[CircleTimes[c,#]&,{a,b}],
CircleTimes[Times[a_?CoefficientQ,b__],c_]:> a*CircleTimes[Times[b],c],
CircleTimes[Times[b__,a_?CoefficientQ],c_]:> a*CircleTimes[Times[b],c],
CircleTimes[c_,Times[a_?CoefficientQ,b__]]:> a*CircleTimes[c,Times[b]],
CircleTimes[c_,Times[b__,a_?CoefficientQ]]:> a*CircleTimes[c,Times[b]],
(* Conjugate *)
Conjugate[Plus[a_,b__]]:>Plus@@Map[Conjugate,{a,b}],
Conjugate[Times[a_,b__]]:>Times@@Map[Conjugate,{a,b}],
Conjugate[Dot[a_,b__]]:>Dot@@Map[Conjugate,{a,b}],
Conjugate[CircleTimes[a_,b__]]:>CircleTimes@@Map[Conjugate,{a,b}],
Conjugate[Transpose[a_]]:> Transpose[Conjugate[a]],
(* Transpose *)
Transpose[a_?CoefficientQ]:> a,
Transpose[Transpose[a_]]:> a,
Transpose[Plus[a_,b__]]:> Plus@@Map[Transpose,{a,b}],
Transpose[Times[a_,b__]]:> Times@@Map[Transpose,{a,b}],
Transpose[Dot[a_,b__]]:> Dot@@Map[Transpose,Reverse[{a,b}]],
Transpose[CircleTimes[a_,b__]]:>CircleTimes@@Map[Transpose,{a,b}],
(* ConjugateTranspose *)
ConjugateTranspose[a_?CoefficientQ]:> Conjugate[a],
ConjugateTranspose[ConjugateTranspose[a_]]:> a,
ConjugateTranspose[a_]:> Transpose[Conjugate[a]],
(* Com *)
Com[a_?CoefficientQ,b_]:> 0,
Com[a_,b_?CoefficientQ]:> 0,
Com[Plus[a_,b__],c_]:> Plus@@Map[Com[#,c]&,{a,b}],
Com[c_,Plus[a_,b__]]:> Plus@@Map[Com[c,#]&,{a,b}],
Com[Times[a_?CoefficientQ,b__],c_]:> a*Com[Times[b],c],
Com[Times[b__,a_?CoefficientQ],c_]:> a*Com[Times[b],c],
Com[c_,Times[a_?CoefficientQ,b__]]:> a*Com[c,Times[b]],
Com[c_,Times[b__,a_?CoefficientQ]]:> a*Com[c,Times[b]],
Com[Dot[a_,b__],c_]:> Dot[a,Com[Dot[b],c]]+Dot[Com[a,c],Dot[b]],
Com[a_,Dot[b_,c__]]:> Dot[Com[a,b],Dot[c]]+Dot[b,Com[a,Dot[c]]],
Com[QPower[a_,n_],b_]:> Dot[a,Com[QPower[a,n-1],b]]+Dot[Com[a,b],QPower[a,n-1]],
Com[a_,QPower[b_,n_]]:> Dot[b,Com[a,QPower[b,n-1]]]+Dot[Com[a,b],QPower[b,n-1]],
Com[CircleTimes[a1_,b1__],CircleTimes[a2_,b2__]]:>
CircleTimes[Com[a1,a2],Dot[CircleTimes[b1],CircleTimes[b2]]]