-
Notifications
You must be signed in to change notification settings - Fork 1.5k
/
Copy pathctrsmf.f
459 lines (456 loc) · 15.3 KB
/
ctrsmf.f
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
SUBROUTINE CTRSMF ( SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA,
$ B, LDB )
* .. Scalar Arguments ..
CHARACTER*1 SIDE, UPLO, TRANSA, DIAG
INTEGER M, N, LDA, LDB
COMPLEX ALPHA
* .. Array Arguments ..
COMPLEX A( LDA, * ), B( LDB, * )
* ..
*
* Purpose
* =======
*
* CTRSM solves one of the matrix equations
*
* op( A )*X = alpha*B, or X*op( A ) = alpha*B,
*
* where alpha is a scalar, X and B are m by n matrices, A is a unit, or
* non-unit, upper or lower triangular matrix and op( A ) is one of
*
* op( A ) = A or op( A ) = A' or op( A ) = conjg( A' ).
*
* The matrix X is overwritten on B.
*
* Parameters
* ==========
*
* SIDE - CHARACTER*1.
* On entry, SIDE specifies whether op( A ) appears on the left
* or right of X as follows:
*
* SIDE = 'L' or 'l' op( A )*X = alpha*B.
*
* SIDE = 'R' or 'r' X*op( A ) = alpha*B.
*
* Unchanged on exit.
*
* UPLO - CHARACTER*1.
* On entry, UPLO specifies whether the matrix A is an upper or
* lower triangular matrix as follows:
*
* UPLO = 'U' or 'u' A is an upper triangular matrix.
*
* UPLO = 'L' or 'l' A is a lower triangular matrix.
*
* Unchanged on exit.
*
* TRANSA - CHARACTER*1.
* On entry, TRANSA specifies the form of op( A ) to be used in
* the matrix multiplication as follows:
*
* TRANSA = 'N' or 'n' op( A ) = A.
*
* TRANSA = 'T' or 't' op( A ) = A'.
*
* TRANSA = 'C' or 'c' op( A ) = conjg( A' ).
*
* Unchanged on exit.
*
* DIAG - CHARACTER*1.
* On entry, DIAG specifies whether or not A is unit triangular
* as follows:
*
* DIAG = 'U' or 'u' A is assumed to be unit triangular.
*
* DIAG = 'N' or 'n' A is not assumed to be unit
* triangular.
*
* Unchanged on exit.
*
* M - INTEGER.
* On entry, M specifies the number of rows of B. M must be at
* least zero.
* Unchanged on exit.
*
* N - INTEGER.
* On entry, N specifies the number of columns of B. N must be
* at least zero.
* Unchanged on exit.
*
* ALPHA - COMPLEX .
* On entry, ALPHA specifies the scalar alpha. When alpha is
* zero then A is not referenced and B need not be set before
* entry.
* Unchanged on exit.
*
* A - COMPLEX array of DIMENSION ( LDA, k ), where k is m
* when SIDE = 'L' or 'l' and is n when SIDE = 'R' or 'r'.
* Before entry with UPLO = 'U' or 'u', the leading k by k
* upper triangular part of the array A must contain the upper
* triangular matrix and the strictly lower triangular part of
* A is not referenced.
* Before entry with UPLO = 'L' or 'l', the leading k by k
* lower triangular part of the array A must contain the lower
* triangular matrix and the strictly upper triangular part of
* A is not referenced.
* Note that when DIAG = 'U' or 'u', the diagonal elements of
* A are not referenced either, but are assumed to be unity.
* Unchanged on exit.
*
* LDA - INTEGER.
* On entry, LDA specifies the first dimension of A as declared
* in the calling (sub) program. When SIDE = 'L' or 'l' then
* LDA must be at least max( 1, m ), when SIDE = 'R' or 'r'
* then LDA must be at least max( 1, n ).
* Unchanged on exit.
*
* B - COMPLEX array of DIMENSION ( LDB, n ).
* Before entry, the leading m by n part of the array B must
* contain the right-hand side matrix B, and on exit is
* overwritten by the solution matrix X.
*
* LDB - INTEGER.
* On entry, LDB specifies the first dimension of B as declared
* in the calling (sub) program. LDB must be at least
* max( 1, m ).
* Unchanged on exit.
*
*
* Level 3 Blas routine.
*
* -- Written on 8-February-1989.
* Jack Dongarra, Argonne National Laboratory.
* Iain Duff, AERE Harwell.
* Jeremy Du Croz, Numerical Algorithms Group Ltd.
* Sven Hammarling, Numerical Algorithms Group Ltd.
*
*
* .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
* .. External Subroutines ..
EXTERNAL XERBLA
* .. Intrinsic Functions ..
INTRINSIC CONJG, MAX
* .. Local Scalars ..
LOGICAL LSIDE, NOCONJ, NOUNIT, UPPER
INTEGER I, INFO, J, K, NROWA
COMPLEX TEMP
* .. Parameters ..
COMPLEX ONE
PARAMETER ( ONE = ( 1.0E+0, 0.0E+0 ) )
COMPLEX ZERO
PARAMETER ( ZERO = ( 0.0E+0, 0.0E+0 ) )
* ..
* .. Executable Statements ..
*
* Test the input parameters.
*
LSIDE = LSAME( SIDE , 'L' )
IF( LSIDE )THEN
NROWA = M
ELSE
NROWA = N
END IF
NOCONJ = (LSAME( TRANSA, 'N' ) .OR. LSAME( TRANSA, 'T' ))
NOUNIT = LSAME( DIAG , 'N' )
UPPER = LSAME( UPLO , 'U' )
*
INFO = 0
IF( ( .NOT.LSIDE ).AND.
$ ( .NOT.LSAME( SIDE , 'R' ) ) )THEN
INFO = 1
ELSE IF( ( .NOT.UPPER ).AND.
$ ( .NOT.LSAME( UPLO , 'L' ) ) )THEN
INFO = 2
ELSE IF( ( .NOT.LSAME( TRANSA, 'N' ) ).AND.
$ ( .NOT.LSAME( TRANSA, 'T' ) ).AND.
$ ( .NOT.LSAME( TRANSA, 'R' ) ).AND.
$ ( .NOT.LSAME( TRANSA, 'C' ) ) )THEN
INFO = 3
ELSE IF( ( .NOT.LSAME( DIAG , 'U' ) ).AND.
$ ( .NOT.LSAME( DIAG , 'N' ) ) )THEN
INFO = 4
ELSE IF( M .LT.0 )THEN
INFO = 5
ELSE IF( N .LT.0 )THEN
INFO = 6
ELSE IF( LDA.LT.MAX( 1, NROWA ) )THEN
INFO = 9
ELSE IF( LDB.LT.MAX( 1, M ) )THEN
INFO = 11
END IF
IF( INFO.NE.0 )THEN
CALL XERBLA( 'CTRSM ', INFO )
RETURN
END IF
*
* Quick return if possible.
*
IF( N.EQ.0 )
$ RETURN
*
* And when alpha.eq.zero.
*
IF( ALPHA.EQ.ZERO )THEN
DO 20, J = 1, N
DO 10, I = 1, M
B( I, J ) = ZERO
10 CONTINUE
20 CONTINUE
RETURN
END IF
*
* Start the operations.
*
IF( LSIDE )THEN
IF( LSAME( TRANSA, 'N' ) .OR. LSAME( TRANSA, 'R' ))THEN
*
* Form B := alpha*inv( A )*B.
*
IF( UPPER )THEN
DO 60, J = 1, N
IF( ALPHA.NE.ONE )THEN
DO 30, I = 1, M
B( I, J ) = ALPHA*B( I, J )
30 CONTINUE
END IF
DO 50, K = M, 1, -1
IF( B( K, J ).NE.ZERO )THEN
IF( NOUNIT ) THEN
IF (NOCONJ) THEN
B( K, J ) = B( K, J )/A( K, K )
ELSE
B( K, J ) = B( K, J )/CONJG(A( K, K ))
ENDIF
ENDIF
IF (NOCONJ) THEN
DO 40, I = 1, K - 1
B( I, J ) = B( I, J ) - B( K, J )*A( I, K )
40 CONTINUE
ELSE
DO 45, I = 1, K - 1
B( I, J ) = B( I, J ) - B( K, J )*CONJG(A( I, K ))
45 CONTINUE
ENDIF
ENDIF
50 CONTINUE
60 CONTINUE
ELSE
DO 100, J = 1, N
IF( ALPHA.NE.ONE )THEN
DO 70, I = 1, M
B( I, J ) = ALPHA*B( I, J )
70 CONTINUE
END IF
DO 90 K = 1, M
IF (NOCONJ) THEN
IF( B( K, J ).NE.ZERO )THEN
IF( NOUNIT )
$ B( K, J ) = B( K, J )/A( K, K )
DO 80, I = K + 1, M
B( I, J ) = B( I, J ) - B( K, J )*A( I, K )
80 CONTINUE
END IF
ELSE
IF( B( K, J ).NE.ZERO )THEN
IF( NOUNIT )
$ B( K, J ) = B( K, J )/CONJG(A( K, K ))
DO 85, I = K + 1, M
B( I, J ) = B( I, J ) - B( K, J )*CONJG(A( I, K ))
85 CONTINUE
END IF
ENDIF
90 CONTINUE
100 CONTINUE
END IF
ELSE
*
* Form B := alpha*inv( A' )*B
* or B := alpha*inv( conjg( A' ) )*B.
*
IF( UPPER )THEN
DO 140, J = 1, N
DO 130, I = 1, M
TEMP = ALPHA*B( I, J )
IF( NOCONJ )THEN
DO 110, K = 1, I - 1
TEMP = TEMP - A( K, I )*B( K, J )
110 CONTINUE
IF( NOUNIT )
$ TEMP = TEMP/A( I, I )
ELSE
DO 120, K = 1, I - 1
TEMP = TEMP - CONJG( A( K, I ) )*B( K, J )
120 CONTINUE
IF( NOUNIT )
$ TEMP = TEMP/CONJG( A( I, I ) )
END IF
B( I, J ) = TEMP
130 CONTINUE
140 CONTINUE
ELSE
DO 180, J = 1, N
DO 170, I = M, 1, -1
TEMP = ALPHA*B( I, J )
IF( NOCONJ )THEN
DO 150, K = I + 1, M
TEMP = TEMP - A( K, I )*B( K, J )
150 CONTINUE
IF( NOUNIT )
$ TEMP = TEMP/A( I, I )
ELSE
DO 160, K = I + 1, M
TEMP = TEMP - CONJG( A( K, I ) )*B( K, J )
160 CONTINUE
IF( NOUNIT )
$ TEMP = TEMP/CONJG( A( I, I ) )
END IF
B( I, J ) = TEMP
170 CONTINUE
180 CONTINUE
END IF
END IF
ELSE
IF( LSAME( TRANSA, 'N' ) .OR. LSAME( TRANSA, 'R' ))THEN
*
* Form B := alpha*B*inv( A ).
*
IF( UPPER )THEN
DO 230, J = 1, N
IF( ALPHA.NE.ONE )THEN
DO 190, I = 1, M
B( I, J ) = ALPHA*B( I, J )
190 CONTINUE
END IF
DO 210, K = 1, J - 1
IF( A( K, J ).NE.ZERO )THEN
IF (NOCONJ) THEN
DO 200, I = 1, M
B( I, J ) = B( I, J ) - A( K, J )*B( I, K )
200 CONTINUE
ELSE
DO 205, I = 1, M
B( I, J ) = B( I, J ) - CONJG(A( K, J ))*B( I, K )
205 CONTINUE
ENDIF
END IF
210 CONTINUE
IF( NOUNIT )THEN
IF (NOCONJ) THEN
TEMP = ONE/A( J, J )
ELSE
TEMP = ONE/CONJG(A( J, J ))
ENDIF
DO 220, I = 1, M
B( I, J ) = TEMP*B( I, J )
220 CONTINUE
END IF
230 CONTINUE
ELSE
DO 280, J = N, 1, -1
IF( ALPHA.NE.ONE )THEN
DO 240, I = 1, M
B( I, J ) = ALPHA*B( I, J )
240 CONTINUE
END IF
DO 260, K = J + 1, N
IF( A( K, J ).NE.ZERO )THEN
IF (NOCONJ) THEN
DO 250, I = 1, M
B( I, J ) = B( I, J ) - A( K, J )*B( I, K )
250 CONTINUE
ELSE
DO 255, I = 1, M
B( I, J ) = B( I, J ) - CONJG(A( K, J ))*B( I, K )
255 CONTINUE
ENDIF
END IF
260 CONTINUE
IF( NOUNIT )THEN
IF (NOCONJ) THEN
TEMP = ONE/A( J, J )
ELSE
TEMP = ONE/CONJG(A( J, J ))
ENDIF
DO 270, I = 1, M
B( I, J ) = TEMP*B( I, J )
270 CONTINUE
END IF
280 CONTINUE
END IF
ELSE
*
* Form B := alpha*B*inv( A' )
* or B := alpha*B*inv( conjg( A' ) ).
*
IF( UPPER )THEN
DO 330, K = N, 1, -1
IF( NOUNIT )THEN
IF( NOCONJ )THEN
TEMP = ONE/A( K, K )
ELSE
TEMP = ONE/CONJG( A( K, K ) )
END IF
DO 290, I = 1, M
B( I, K ) = TEMP*B( I, K )
290 CONTINUE
END IF
DO 310, J = 1, K - 1
IF( A( J, K ).NE.ZERO )THEN
IF( NOCONJ )THEN
TEMP = A( J, K )
ELSE
TEMP = CONJG( A( J, K ) )
END IF
DO 300, I = 1, M
B( I, J ) = B( I, J ) - TEMP*B( I, K )
300 CONTINUE
END IF
310 CONTINUE
IF( ALPHA.NE.ONE )THEN
DO 320, I = 1, M
B( I, K ) = ALPHA*B( I, K )
320 CONTINUE
END IF
330 CONTINUE
ELSE
DO 380, K = 1, N
IF( NOUNIT )THEN
IF( NOCONJ )THEN
TEMP = ONE/A( K, K )
ELSE
TEMP = ONE/CONJG( A( K, K ) )
END IF
DO 340, I = 1, M
B( I, K ) = TEMP*B( I, K )
340 CONTINUE
END IF
DO 360, J = K + 1, N
IF( A( J, K ).NE.ZERO )THEN
IF( NOCONJ )THEN
TEMP = A( J, K )
ELSE
TEMP = CONJG( A( J, K ) )
END IF
DO 350, I = 1, M
B( I, J ) = B( I, J ) - TEMP*B( I, K )
350 CONTINUE
END IF
360 CONTINUE
IF( ALPHA.NE.ONE )THEN
DO 370, I = 1, M
B( I, K ) = ALPHA*B( I, K )
370 CONTINUE
END IF
380 CONTINUE
END IF
END IF
END IF
*
RETURN
*
* End of CTRSM .
*
END