|
| 1 | +#include <PPP.h> |
| 2 | + |
| 3 | +#define PPP_MODEM_APN "internet" |
| 4 | +#define PPP_MODEM_PIN "0000" // or NULL |
| 5 | + |
| 6 | +// WaveShare SIM7600 HW Flow Control |
| 7 | +#define PPP_MODEM_RST 25 |
| 8 | +#define PPP_MODEM_RST_LOW false //active HIGH |
| 9 | +#define PPP_MODEM_TX 21 |
| 10 | +#define PPP_MODEM_RX 22 |
| 11 | +#define PPP_MODEM_RTS 26 |
| 12 | +#define PPP_MODEM_CTS 27 |
| 13 | +#define PPP_MODEM_FC ESP_MODEM_FLOW_CONTROL_HW |
| 14 | +#define PPP_MODEM_MODEL PPP_MODEM_SIM7600 |
| 15 | + |
| 16 | +// SIM800 basic module with just TX,RX and RST |
| 17 | +// #define PPP_MODEM_RST 0 |
| 18 | +// #define PPP_MODEM_RST_LOW true //active LOW |
| 19 | +// #define PPP_MODEM_TX 2 |
| 20 | +// #define PPP_MODEM_RX 19 |
| 21 | +// #define PPP_MODEM_RTS -1 |
| 22 | +// #define PPP_MODEM_CTS -1 |
| 23 | +// #define PPP_MODEM_FC ESP_MODEM_FLOW_CONTROL_NONE |
| 24 | +// #define PPP_MODEM_MODEL PPP_MODEM_SIM800 |
| 25 | + |
| 26 | +void onEvent(arduino_event_id_t event, arduino_event_info_t info) { |
| 27 | + switch (event) { |
| 28 | + case ARDUINO_EVENT_PPP_START: |
| 29 | + Serial.println("PPP Started"); |
| 30 | + break; |
| 31 | + case ARDUINO_EVENT_PPP_CONNECTED: |
| 32 | + Serial.println("PPP Connected"); |
| 33 | + break; |
| 34 | + case ARDUINO_EVENT_PPP_GOT_IP: |
| 35 | + Serial.println("PPP Got IP"); |
| 36 | + break; |
| 37 | + case ARDUINO_EVENT_PPP_LOST_IP: |
| 38 | + Serial.println("PPP Lost IP"); |
| 39 | + break; |
| 40 | + case ARDUINO_EVENT_PPP_DISCONNECTED: |
| 41 | + Serial.println("PPP Disconnected"); |
| 42 | + break; |
| 43 | + case ARDUINO_EVENT_PPP_STOP: |
| 44 | + Serial.println("PPP Stopped"); |
| 45 | + break; |
| 46 | + default: |
| 47 | + break; |
| 48 | + } |
| 49 | +} |
| 50 | + |
| 51 | +void testClient(const char* host, uint16_t port) { |
| 52 | + NetworkClient client; |
| 53 | + if (!client.connect(host, port)) { |
| 54 | + Serial.println("Connection Failed"); |
| 55 | + return; |
| 56 | + } |
| 57 | + client.printf("GET / HTTP/1.1\r\nHost: %s\r\n\r\n", host); |
| 58 | + while (client.connected() && !client.available()) |
| 59 | + ; |
| 60 | + while (client.available()) { |
| 61 | + client.read(); //Serial.write(client.read()); |
| 62 | + } |
| 63 | + |
| 64 | + Serial.println("Connection Success"); |
| 65 | + client.stop(); |
| 66 | +} |
| 67 | + |
| 68 | +void setup() { |
| 69 | + Serial.begin(115200); |
| 70 | + |
| 71 | + // Listen for modem events |
| 72 | + Network.onEvent(onEvent); |
| 73 | + |
| 74 | + // Configure the modem |
| 75 | + PPP.setApn(PPP_MODEM_APN); |
| 76 | + PPP.setPin(PPP_MODEM_PIN); |
| 77 | + PPP.setResetPin(PPP_MODEM_RST, PPP_MODEM_RST_LOW); |
| 78 | + PPP.setPins(PPP_MODEM_TX, PPP_MODEM_RX, PPP_MODEM_RTS, PPP_MODEM_CTS, PPP_MODEM_FC); |
| 79 | + |
| 80 | + Serial.println("Starting the modem. It might take a while!"); |
| 81 | + PPP.begin(PPP_MODEM_MODEL); |
| 82 | + |
| 83 | + Serial.print("Manufacturer: "); |
| 84 | + Serial.println(PPP.cmd("AT+CGMI", 10000)); |
| 85 | + Serial.print("Model: "); |
| 86 | + Serial.println(PPP.moduleName()); |
| 87 | + Serial.print("IMEI: "); |
| 88 | + Serial.println(PPP.IMEI()); |
| 89 | + |
| 90 | + bool attached = PPP.attached(); |
| 91 | + if (!attached) { |
| 92 | + int i = 0; |
| 93 | + unsigned int s = millis(); |
| 94 | + Serial.print("Waiting to connect to network"); |
| 95 | + while (!attached && ((++i) < 600)) { |
| 96 | + Serial.print("."); |
| 97 | + delay(100); |
| 98 | + attached = PPP.attached(); |
| 99 | + } |
| 100 | + Serial.print((millis() - s) / 1000.0, 1); |
| 101 | + Serial.println("s"); |
| 102 | + attached = PPP.attached(); |
| 103 | + } |
| 104 | + |
| 105 | + Serial.print("Attached: "); |
| 106 | + Serial.println(attached); |
| 107 | + Serial.print("State: "); |
| 108 | + Serial.println(PPP.radioState()); |
| 109 | + if (attached) { |
| 110 | + Serial.print("Operator: "); |
| 111 | + Serial.println(PPP.operatorName()); |
| 112 | + Serial.print("IMSI: "); |
| 113 | + Serial.println(PPP.IMSI()); |
| 114 | + Serial.print("RSSI: "); |
| 115 | + Serial.println(PPP.RSSI()); |
| 116 | + int ber = PPP.BER(); |
| 117 | + if (ber > 0) { |
| 118 | + Serial.print("BER: "); |
| 119 | + Serial.println(ber); |
| 120 | + Serial.print("NetMode: "); |
| 121 | + Serial.println(PPP.networkMode()); |
| 122 | + } |
| 123 | + |
| 124 | + Serial.println("Switching to data mode..."); |
| 125 | + PPP.mode(ESP_MODEM_MODE_CMUX); // Data and Command mixed mode |
| 126 | + if (!PPP.waitStatusBits(ESP_NETIF_CONNECTED_BIT, 1000)) { |
| 127 | + Serial.println("Failed to connect to internet!"); |
| 128 | + } else { |
| 129 | + Serial.println("Connected to internet!"); |
| 130 | + } |
| 131 | + } else { |
| 132 | + Serial.println("Failed to connect to network!"); |
| 133 | + } |
| 134 | +} |
| 135 | + |
| 136 | +void loop() { |
| 137 | + if (PPP.connected()) { |
| 138 | + testClient("google.com", 80); |
| 139 | + } |
| 140 | + delay(20000); |
| 141 | +} |
![pre-commit-ci-lite[bot]](https://avatars.githubusercontent.com/in/257897?v=4&size=40){kind=avatar}
0 commit comments