forked from swiftlang/swift-corelibs-foundation
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathSwiftSupport.cmake
260 lines (245 loc) · 9.86 KB
/
SwiftSupport.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
include(CMakeParseArguments)
# Creates an output file map give a target and its list of sources at
# output_path
#
# Usage:
# create_output_file_map(target sources output_path)
function(create_output_file_map target sources output_path)
set(output_list)
set(output_file_map "{\n")
foreach(source ${sources})
get_filename_component(name ${source} NAME)
set(obj ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${name}${CMAKE_C_OUTPUT_EXTENSION})
set(deps ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${name}.d)
set(swiftdeps ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${name}.swiftdeps)
set(dia ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${name}.dia)
set(output_entry "\"${source}\": {\n\
\"object\": \"${obj}\",\n\
\"dependencies\": \"${deps}\",\n\
\"swift-dependencies\": \"${swiftdeps}\",\n\
\"diagnostics\": \"${dia}\"\n\
},\n")
string(APPEND output_file_map ${output_entry})
endforeach()
set(master_deps ${CMAKE_CURRENT_BINARY_DIR}/${target}.swiftdeps)
string(APPEND output_file_map "\"\": {\n\
\"swift-dependencies\": \"${master_deps}\"\n\
}\n")
string(APPEND output_file_map "}\n")
file(WRITE ${output_path} ${output_file_map})
endfunction()
function(add_swift_target target)
set(options LIBRARY;SHARED;STATIC)
set(single_value_options MODULE_NAME;MODULE_LINK_NAME;MODULE_PATH;MODULE_CACHE_PATH;OUTPUT;TARGET)
set(multiple_value_options CFLAGS;DEPENDS;LINK_FLAGS;RESOURCES;SOURCES;SWIFT_FLAGS)
cmake_parse_arguments(AST "${options}" "${single_value_options}" "${multiple_value_options}" ${ARGN})
set(compile_flags ${CMAKE_SWIFT_FLAGS})
set(link_flags)
list(APPEND compile_flags -incremental)
if(AST_TARGET)
list(APPEND compile_flags -target;${AST_TARGET})
list(APPEND link_flags -target;${AST_TARGET})
endif()
if(AST_MODULE_NAME)
list(APPEND compile_flags -module-name;${AST_MODULE_NAME})
else()
list(APPEND compile_flags -module-name;${target})
endif()
if(AST_MODULE_LINK_NAME)
list(APPEND compile_flags -module-link-name;${AST_MODULE_LINK_NAME})
endif()
if(AST_MODULE_CACHE_PATH)
list(APPEND compile_flags -module-cache-path;${AST_MODULE_CACHE_PATH})
endif()
if(AST_MODULE_PATH)
get_filename_component(module_location ${AST_MODULE_PATH} PATH)
file(MAKE_DIRECTORY "${module_location}")
list(APPEND compile_flags "-emit-module-path;${AST_MODULE_PATH}")
endif()
if(CMAKE_BUILD_TYPE MATCHES Debug OR CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
list(APPEND compile_flags -g)
endif()
if(AST_SWIFT_FLAGS)
foreach(flag ${AST_SWIFT_FLAGS})
list(APPEND compile_flags ${flag})
endforeach()
endif()
if(AST_CFLAGS)
foreach(flag ${AST_CFLAGS})
list(APPEND compile_flags -Xcc;${flag})
endforeach()
endif()
if(AST_LINK_FLAGS)
foreach(flag ${AST_LINK_FLAGS})
list(APPEND link_flags ${flag})
endforeach()
endif()
if(AST_LIBRARY)
if(AST_STATIC AND AST_SHARED)
message(SEND_ERROR "add_swift_target asked to create library as STATIC and SHARED")
elseif(AST_STATIC OR NOT BUILD_SHARED_LIBS)
set(library_kind STATIC)
elseif(AST_SHARED OR BUILD_SHARED_LIBS)
set(library_kind SHARED)
endif()
else()
if(AST_STATIC OR AST_SHARED)
message(SEND_ERROR "add_swift_target asked to create executable as STATIC or SHARED")
endif()
endif()
if(NOT AST_OUTPUT)
if(AST_LIBRARY)
if(AST_SHARED OR BUILD_SHARED_LIBS)
set(AST_OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${CMAKE_SHARED_LIBRARY_PREFIX}${target}${CMAKE_SHARED_LIBRARY_SUFFIX})
else()
set(AST_OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${CMAKE_STATIC_LIBRARY_PREFIX}${target}${CMAKE_STATIC_LIBRARY_SUFFIX})
endif()
else()
set(AST_OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${target}${CMAKE_EXECUTABLE_SUFFIX})
endif()
endif()
if(CMAKE_SYSTEM_NAME STREQUAL Windows)
if(AST_SHARED OR BUILD_SHARED_LIBS)
set(IMPORT_LIBRARY ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${CMAKE_IMPORT_LIBRARY_PREFIX}${target}${CMAKE_IMPORT_LIBRARY_SUFFIX})
endif()
endif()
set(sources)
set(rsp_text)
foreach(source ${AST_SOURCES})
get_filename_component(location ${source} PATH)
if(IS_ABSOLUTE ${location})
list(APPEND sources ${source})
string(APPEND rsp_text "${source} ")
else()
list(APPEND sources ${CMAKE_CURRENT_SOURCE_DIR}/${source})
string(APPEND rsp_text "${CMAKE_CURRENT_SOURCE_DIR}/${source} ")
endif()
endforeach()
set(output_map_path ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/output-file-map.json)
create_output_file_map(${target} "${sources}" ${output_map_path})
list(APPEND compile_flags -output-file-map;${output_map_path})
string(LENGTH sources source_length)
set(rsp_file ${CMAKE_CURRENT_BINARY_DIR}/${target}.dir/${target}.rsp)
file(WRITE ${rsp_file} ${rsp_text})
if(AST_LIBRARY)
set(emit_library -emit-library)
endif()
if(NOT AST_LIBRARY OR library_kind STREQUAL SHARED)
add_custom_command(OUTPUT
${AST_OUTPUT}
DEPENDS
${sources}
${AST_DEPENDS}
COMMAND
${CMAKE_SWIFT_COMPILER} ${emit_library} ${compile_flags} ${link_flags} -o ${AST_OUTPUT} @${rsp_file})
add_custom_target(${target}
ALL
DEPENDS
${AST_OUTPUT}
${module}
${documentation})
else()
add_library(${target}-static STATIC ${sources})
if(AST_DEPENDS)
add_dependencies(${target}-static ${AST_DEPENDS})
endif()
get_filename_component(ast_output_bn ${AST_OUTPUT} NAME)
if(NOT CMAKE_STATIC_LIBRARY_PREFIX STREQUAL "")
string(REGEX REPLACE "^${CMAKE_STATIC_LIBRARY_PREFIX}" "" ast_output_bn ${ast_output_bn})
endif()
if(NOT CMAKE_STATIC_LIBRARY_SUFFIX STREQUAL "")
string(REGEX REPLACE "${CMAKE_STATIC_LIBRARY_SUFFIX}$" "" ast_output_bn ${ast_output_bn})
endif()
get_filename_component(ast_output_dn ${AST_OUTPUT} DIRECTORY)
set_target_properties(${target}-static
PROPERTIES
LINKER_LANGUAGE C
ARCHIVE_OUTPUT_DIRECTORY ${ast_output_dn}
OUTPUT_DIRECTORY ${ast_output_dn}
OUTPUT_NAME ${ast_output_bn})
add_custom_target(${target}
ALL
DEPENDS
${target}-static
${module}
${documentation})
endif()
if(AST_RESOURCES)
if(CMAKE_SYSTEM_NAME STREQUAL Windows)
set(resources_dir ${target}.resources)
else()
set(resources_dir Resources)
endif()
add_custom_command(TARGET
${target}
POST_BUILD
COMMAND
${CMAKE_COMMAND} -E make_directory ${CMAKE_CURRENT_BINARY_DIR}/${target}
COMMAND
${CMAKE_COMMAND} -E copy ${AST_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${target}
COMMAND
${CMAKE_COMMAND} -E make_directory ${CMAKE_CURRENT_BINARY_DIR}/${target}/${resources_dir})
foreach(resource ${AST_RESOURCES})
add_custom_command(TARGET
${target}
POST_BUILD
COMMAND
${CMAKE_COMMAND} -E copy ${resource} ${CMAKE_CURRENT_BINARY_DIR}/${target}/${resources_dir}/)
endforeach()
else()
add_custom_command(TARGET
${target}
POST_BUILD
COMMAND
${CMAKE_COMMAND} -E copy ${AST_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR})
if(CMAKE_SYSTEM_NAME STREQUAL Windows)
if(AST_SHARED OR BUILD_SHARED_LIBS)
add_custom_command(TARGET
${target}
POST_BUILD
COMMAND
${CMAKE_COMMAND} -E copy ${IMPORT_LIBRARY} ${CMAKE_CURRENT_BINARY_DIR})
endif()
endif()
endif()
endfunction()
function(add_swift_library library)
add_swift_target(${library} LIBRARY ${ARGN})
endfunction()
function(add_swift_executable executable)
add_swift_target(${executable} ${ARGN})
endfunction()
# Returns the current achitecture name in a variable
#
# Usage:
# get_swift_host_arch(result_var_name)
#
# If the current architecture is supported by Swift, sets ${result_var_name}
# with the sanitized host architecture name derived from CMAKE_SYSTEM_PROCESSOR.
function(get_swift_host_arch result_var_name)
if("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64")
set("${result_var_name}" "x86_64" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "aarch64")
set("${result_var_name}" "aarch64" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "ppc64")
set("${result_var_name}" "powerpc64" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "ppc64le")
set("${result_var_name}" "powerpc64le" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "s390x")
set("${result_var_name}" "s390x" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "armv6l")
set("${result_var_name}" "armv6" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "armv7l")
set("${result_var_name}" "armv7" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "AMD64")
set("${result_var_name}" "x86_64" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "IA64")
set("${result_var_name}" "itanium" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86")
set("${result_var_name}" "i686" PARENT_SCOPE)
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "i686")
set("${result_var_name}" "i686" PARENT_SCOPE)
else()
message(FATAL_ERROR "Unrecognized architecture on host system: ${CMAKE_SYSTEM_PROCESSOR}")
endif()
endfunction()